Ensure that PATH_INFO and REQUEST_URI are following the CGI specifications:

- PATH_INFO is percent decoded but still utf-8 encoded,
  this is available via WGI.path_info and WSF_REQUEST.utf_8_path_info.
- Added WSF_REQUEST.percent_encoded_path_info
- and WSF_REQUEST.path_info remains the unicode value for PATH_INFO

Added cgi_variables: WGI_REQUEST_CGI_VARIABLES to have a simple and quick view on CGI variables
Added execution_variables to be able to iterate on execution variables.
Added PERCENT_ENCODER.percent_decoded_utf_8_string
Improved the WSF_DEBUG_HANDLER to provide more information thanks to WSF_DEBUG_INFORMATION object.

library/server/ewsgi/connectors/nino/src/wgi_nino_handler.e

@@ -74,8 +74,8 @@ feature -- Request processing
 			l_request_uri := a_handler.uri
 			l_headers_map := a_handler.request_header_map
 			create e
-			if attached e.starting_environment as vars then
 			create enc
+			if attached e.starting_environment as vars then
 				create env.make_equal (vars.count)
 				across
 					vars as c
@@ -168,8 +168,22 @@ feature -- Request processing
 					if p > 0 then
 						l_path_info.keep_head (p - 1)
 					end
-					env.force (l_path_info, "PATH_INFO")
+					env.force (enc.decoded_utf_8_string (l_path_info), "PATH_INFO")
 					env.force (l_base, "SCRIPT_NAME")
+				else
+						-- This should not happen, this means the `base' is not correctly set.
+						-- It is better to consider base as empty, rather than having empty PATH_INFO
+					check valid_base_value: False end
+
+					l_path_info := l_request_uri
+					p := l_request_uri.index_of ('?', 1)
+					if p > 0 then
+						l_path_info := l_request_uri.substring (1, p - 1)
+					else
+						l_path_info := l_request_uri.string
+					end
+					env.force (enc.decoded_utf_8_string (l_path_info), "PATH_INFO")
+					env.force ("", "SCRIPT_NAME")
 				end
 			end
 

library/server/ewsgi/specification/request/wgi_request.e

@@ -88,6 +88,14 @@ feature -- Access: Input
 
 feature -- Access: CGI meta variables
 
+	cgi_variables: WGI_REQUEST_CGI_VARIABLES
+			-- Object containing the CGI variables
+			--| note: a new instance is created on each call!
+			--| this is mainly for debugging purpose.
+		do
+			create Result.make (Current)
+		end
+
 	meta_variable (a_name: READABLE_STRING_GENERAL): detachable READABLE_STRING_8
 			-- Environment variable related to `a_name'
 		require
@@ -297,6 +305,8 @@ feature -- Common Gateway Interface - 1.1       8 January 1996
 			-- The PATH_INFO value is case-sensitive, and the server MUST
 			-- preserve the case of the PATH_INFO element of the URI when
 			-- making it available to scripts.
+			--
+			-- Note: it is UTF-8 encoded, and percent decoded.
 		deferred
 		end
 

library/server/ewsgi/specification/request/wgi_request_cgi_variables.e

@@ -0,0 +1,366 @@
+note
+	description: "[
+			Object containing the CGI variable for a specific WGI request.
+			This is mainly used for debugging purpose.
+		]"
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	WGI_REQUEST_CGI_VARIABLES
+
+inherit
+	DEBUG_OUTPUT
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make (req: WGI_REQUEST)
+			-- Initialize Current from `req'.
+		local
+			utf: UTF_CONVERTER
+		do
+			auth_type := req.auth_type
+			content_length := req.content_length
+			if attached req.content_type as ct then
+				content_type := ct.string
+			else
+				content_type := Void
+			end
+			gateway_interface := req.gateway_interface
+			path_info := req.path_info
+			path_translated := req.path_translated
+			query_string := req.query_string
+			remote_addr := req.remote_addr
+			remote_host := req.remote_host
+			remote_ident := req.remote_ident
+			remote_user := req.remote_user
+			request_method := req.request_method
+			script_name := req.script_name
+			server_name := req.server_name
+			server_port := req.server_port
+			server_protocol := req.server_protocol
+			server_software := req.server_software
+
+			create http_meta_variables.make (0)
+			across
+				req.meta_variables as ic
+			loop
+				if ic.key.starts_with ("HTTP_") then
+					if ic.key.is_valid_as_string_8 then
+						http_meta_variables.force (ic.item, ic.key.as_string_8)
+					else
+						http_meta_variables.force (ic.item, utf.escaped_utf_32_string_to_utf_8_string_8 (ic.key))
+					end
+				end
+			end
+		end
+
+feature -- Status report
+
+	debug_output: STRING_32
+			-- <Precursor>
+		do
+			create Result.make (1_024)
+			append_variable_to_debug_output ("AUTH_TYPE", auth_type, Result)
+			append_variable_to_debug_output ("CONTENT_LENGTH", content_length, Result)
+			append_variable_to_debug_output ("CONTENT_TYPE", content_type, Result)
+			append_required_variable_to_debug_output ("GATEWAY_INTERFACE", gateway_interface, Result)
+			across
+				http_meta_variables as ic
+			loop
+				append_variable_to_debug_output (ic.key, ic.item, Result)
+			end
+			append_required_variable_to_debug_output ("PATH_INFO", path_info, Result)
+			append_variable_to_debug_output ("PATH_TRANSLATED", path_translated, Result)
+			append_required_variable_to_debug_output ("QUERY_STRING", query_string, Result)
+			append_required_variable_to_debug_output ("REMOTE_ADDR", remote_addr, Result)
+			append_variable_to_debug_output ("REMOTE_HOST", remote_host, Result)
+			append_variable_to_debug_output ("REMOTE_IDENT", remote_ident, Result)
+			append_variable_to_debug_output ("REMOTE_USER", remote_user, Result)
+			append_required_variable_to_debug_output ("REQUEST_METHOD", request_method, Result)
+			append_variable_to_debug_output ("SCRIPT_NAME", script_name, Result)
+			append_required_variable_to_debug_output ("SERVER_NAME", server_name, Result)
+			append_variable_to_debug_output ("SERVER_PORT", server_port.out, Result)
+			append_variable_to_debug_output ("SERVER_PROTOCOL", request_method, Result)
+			append_variable_to_debug_output ("SERVER_SOFTWARE", server_software, Result)
+		end
+
+feature {NONE} -- Implementation
+
+	append_required_variable_to_debug_output (a_name: READABLE_STRING_8; a_value: READABLE_STRING_GENERAL; a_output: STRING_32)
+		require
+			a_value_not_is_empty: a_value /= Void
+		do
+			a_output.append (a_name)
+			a_output.append_character ('=')
+			a_output.append_string_general (a_value)
+			a_output.append_character ('%N')
+		end
+
+	append_variable_to_debug_output (a_name: READABLE_STRING_8; a_value: detachable READABLE_STRING_GENERAL; a_output: STRING_32)
+		do
+			if a_value /= Void then
+				a_output.append (a_name)
+				a_output.append_character ('=')
+				a_output.append_string_general (a_value)
+				a_output.append_character ('%N')
+			end
+		end
+
+feature -- Access: meta variable
+
+	auth_type: detachable READABLE_STRING_8
+			-- The variable is specific to requests made with HTTP.
+			--
+			-- If the script URI would require access authentication for external
+			-- access, then this variable is found from the `auth-scheme' token
+			-- in the request, otherwise NULL.
+			--
+			-- 	auth-scheme = "Basic" | token
+			--
+			-- HTTP access authentication schemes are described in section 11 of
+			-- the HTTP/1.0 specification [3]. The auth-scheme is not
+			-- case-sensitive.	
+
+	content_length: detachable READABLE_STRING_8
+			-- The size of the entity attached to the request, if any, in decimal
+			-- number of octets. If no data is attached, then NULL. The syntax is
+			-- the same as the HTTP Content-Length header (section 10, HTTP/1.0
+			-- specification [3]).
+			--
+			-- 	 CONTENT_LENGTH = "" | [ 1*digit ]
+
+	content_type: detachable READABLE_STRING_8
+			-- The Internet Media Type [9] of the attached entity. The syntax is
+			-- the same as the HTTP Content-Type header.
+			--
+			--  CONTENT_TYPE = "" | media-type
+			--  media-type   = type "/" subtype *( ";" parameter)
+			--  type         = token
+			--  subtype      = token
+			--  parameter    = attribute "=" value
+			--  attribute    = token
+			--  value        = token | quoted-string
+			--
+			-- The type, subtype and parameter attribute names are not
+			-- case-sensitive. Parameter values may be case sensitive.  Media
+			-- types and their use in HTTP are described section 3.6 of the
+			-- HTTP/1.0 specification [3]. Example:
+			--
+			-- 	application/x-www-form-urlencoded
+			--
+			-- There is no default value for this variable. If and only if it is
+			-- unset, then the script may attempt to determine the media type
+			-- from the data received. If the type remains unknown, then
+			-- application/octet-stream should be assumed.	
+
+	gateway_interface: READABLE_STRING_8
+			-- The version of the CGI specification to which this server
+			-- complies.  Syntax:
+			--
+			--  GATEWAY_INTERFACE =  "CGI" "/" 1*digit "." 1*digit
+			--
+			-- Note that the major and minor numbers are treated as separate
+			-- integers and that each may be incremented higher than a single
+			-- digit.  Thus CGI/2.4 is a lower version than CGI/2.13 which in
+			-- turn is lower than CGI/12.3. Leading zeros must be ignored by
+			-- scripts and should never be generated by servers.
+
+	http_meta_variables: HASH_TABLE [READABLE_STRING_8, READABLE_STRING_8]
+			-- These variables are specific to requests made with HTTP.
+			-- Interpretation of these variables may depend on the value of
+			-- SERVER_PROTOCOL.
+			--
+			-- Environment variables with names beginning with "HTTP_" contain
+			-- header data read from the client, if the protocol used was HTTP.
+			-- The HTTP header name is converted to upper case, has all
+			-- occurrences of "-" replaced with "_" and has "HTTP_" prepended to
+			-- give the environment variable name. The header data may be
+			-- presented as sent by the client, or may be rewritten in ways which
+			-- do not change its semantics. If multiple headers with the same
+			-- field-name are received then they must be rewritten as a single
+			-- header having the same semantics. Similarly, a header that is
+			-- received on more than one line must be merged onto a single line.
+			-- The server must, if necessary, change the representation of the
+			-- data (for example, the character set) to be appropriate for a CGI
+			-- environment variable.
+			--
+			-- The server is not required to create environment variables for all
+			-- the headers that it receives. In particular, it may remove any
+			-- headers carrying authentication information, such as
+			-- "Authorization"; it may remove headers whose value is available to
+			-- the script via other variables, such as "Content-Length" and
+			-- "Content-Type".
+
+	path_info: READABLE_STRING_GENERAL
+			-- A path to be interpreted by the CGI script. It identifies the
+			-- resource or sub-resource to be returned by the CGI script. The
+			-- syntax and semantics are similar to a decoded HTTP URL `hpath'
+			-- token (defined in RFC 1738 [4]), with the exception that a
+			-- PATH_INFO of "/" represents a single void path segment. Otherwise,
+			-- the leading "/" character is not part of the path.
+			--
+			--  PATH_INFO = "" | "/" path
+			--  path      = segment *( "/" segment )
+			--  segment   = *pchar
+			--  pchar     = <any CHAR except "/">
+			--
+			-- The PATH_INFO string is the trailing part of the <path> component
+			-- of the script URI that follows the SCRIPT_NAME part of the path.	
+
+	path_translated: detachable READABLE_STRING_GENERAL
+			-- The OS path to the file that the server would attempt to access
+			-- were the client to request the absolute URL containing the path
+			-- PATH_INFO.  i.e for a request of
+			--
+			--  protocol "://" SERVER_NAME ":" SERVER_PORT enc-path-info
+			--
+			-- where `enc-path-info' is a URL-encoded version of PATH_INFO. If
+			-- PATH_INFO is NULL then PATH_TRANSLATED is set to NULL.
+			--
+			--  PATH_TRANSLATED = *CHAR
+			--
+			-- PATH_TRANSLATED need not be supported by the server. The server
+			-- may choose to set PATH_TRANSLATED to NULL for reasons of security,
+			-- or because the path would not be interpretable by a CGI script;
+			-- such as the object it represented was internal to the server and
+			-- not visible in the file-system; or for any other reason.
+			--
+			-- The algorithm the server uses to derive PATH_TRANSLATED is
+			-- obviously implementation defined; CGI scripts which use this
+			-- variable may suffer limited portability.	
+
+	query_string: READABLE_STRING_GENERAL
+			-- A URL-encoded search string; the <query> part of the script URI.
+			--
+			--  QUERY_STRING = query-string
+			--  query-string = *qchar
+			--  qchar        = unreserved | escape | reserved
+			--  unreserved   = alpha | digit | safe | extra
+			--  reserved     = ";" | "/" | "?" | ":" | "@" | "&" | "="
+			--  safe         = "$" | "-" | "_" | "." | "+"
+			--  extra        = "!" | "*" | "'" | "(" | ")" | ","
+			--  escape       = "%" hex hex
+			--  hex          = digit | "A" | "B" | "C" | "D" | "E" | "F" | "a"
+			-- 			  | "b" | "c" | "d" | "e" | "f"
+			--
+			-- The URL syntax for a search string is described in RFC 1738 [4].	
+
+	remote_addr: READABLE_STRING_GENERAL
+			-- The IP address of the agent sending the request to the server. Not
+			-- necessarily that of the client.
+			--
+			--  REMOTE_ADDR = hostnumber
+			--  hostnumber  = digits "." digits "." digits "." digits
+			--  digits      = 1*digit	
+
+	remote_host: detachable READABLE_STRING_GENERAL
+			-- The fully qualified domain name of the agent sending the request
+			-- to the server, if available, otherwise NULL. Not necessarily that
+			-- of the client. Fully qualified domain names take the form as
+			-- described in section 3.5 of RFC 1034 [8] and section 2.1 of RFC
+			-- 1123 [5]; a sequence of domain labels separated by ".", each
+			-- domain label starting and ending with an alphanumerical character
+			-- and possibly also containing "-" characters. The rightmost domain
+			-- label will never start with a digit. Domain names are not case
+			-- sensitive.
+			--
+			--  REMOTE_HOST   = "" | hostname
+			--  hostname      = *( domainlabel ".") toplabel
+			--  domainlabel   = alphadigit [ *alphahypdigit alphadigit ]
+			--  toplabel      = alpha [ *alphahypdigit alphadigit ]
+			--  alphahypdigit = alphadigit | "-"
+			--  alphadigit    = alpha | digit	
+
+	remote_ident: detachable READABLE_STRING_GENERAL
+			-- The identity information reported about the connection by a RFC
+			-- 931 [10] request to the remote agent, if available. The server may
+			-- choose not to support this feature, or not to request the data for
+			-- efficiency reasons.
+			--
+			--  REMOTE_IDENT = *CHAR
+			--
+			-- The data returned is not appropriate for use as authentication
+			-- information.	
+
+	remote_user: detachable READABLE_STRING_GENERAL
+			-- This variable is specific to requests made with HTTP.
+			--
+			-- If AUTH_TYPE is "Basic", then the user-ID sent by the client. If
+			-- AUTH_TYPE is NULL, then NULL, otherwise undefined.
+			--
+			--  userid      = token	
+
+	request_method: READABLE_STRING_GENERAL
+			-- This variable is specific to requests made with HTTP.
+			--
+			-- The method with which the request was made, as described in
+			-- section 5.1.1 of the HTTP/1.0 specification [3].
+			--
+			--  http-method      = "GET" | "HEAD" | "POST" | extension-method
+			--  extension-method = token
+			--
+			-- The method is case sensitive.	
+
+	script_name: READABLE_STRING_GENERAL
+			-- A URL path that could identify the CGI script (rather then the
+			-- particular CGI output). The syntax and semantics are identical to
+			-- a decoded HTTP URL `hpath' token [4].
+			--
+			--  SCRIPT_NAME = "" | "/" [ path ]
+			--
+			-- The leading "/" is not part of the path. It is optional if the
+			-- path is NULL.
+			--
+			-- The SCRIPT_NAME string is some leading part of the <path>
+			-- component of the script URI derived in some implementation defined
+			-- manner.	
+
+	server_name: READABLE_STRING_GENERAL
+			-- The name for this server, as used in the <host> part of the script
+			-- URI. Thus either a fully qualified domain name, or an IP address.
+			--
+			--  SERVER_NAME = hostname | hostnumber	
+
+	server_port: INTEGER
+			-- The port on which this request was received, as used in the <port>
+			-- part of the script URI.
+			--
+			--  SERVER_PORT = 1*digit	
+
+	server_protocol: READABLE_STRING_GENERAL
+			-- The name and revision of the information protocol this request
+			-- came in with.
+			--
+			--  SERVER_PROTOCOL   = HTTP-Version | extension-version
+			--  HTTP-Version      = "HTTP" "/" 1*digit "." 1*digit
+			--  extension-version = protocol "/" 1*digit "." 1*digit
+			--  protocol          = 1*( alpha | digit | "+" | "-" | "." )
+			--
+			-- `protocol' is a version of the <scheme> part of the script URI,
+			-- and is not case sensitive. By convention, `protocol' is in upper
+			-- case.	
+
+	server_software: READABLE_STRING_GENERAL
+			-- The name and version of the information server software answering
+			-- the request (and running the gateway).
+			--
+			--  SERVER_SOFTWARE = *CHAR	
+
+invariant
+	request_method_set: not request_method.is_empty
+
+note
+	copyright: "2011-2014, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Colin Adams, Eiffel Software and others"
+	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
+	source: "[
+			Eiffel Software
+			5949 Hollister Ave., Goleta, CA 93117 USA
+			Telephone 805-685-1006, Fax 805-685-6869
+			Website http://www.eiffel.com
+			Customer support http://support.eiffel.com
+		]"
+end

library/server/ewsgi/src/implementation/wgi_request_from_table.e

@@ -319,6 +319,7 @@ feature {NONE} -- Element change: CGI meta parameter related to PATH_INFO
 			until
 				a_vars.after
 			loop
+					-- Warning: truncated value to ascii !!!
 				table.force (a_vars.item_for_iteration.to_string_8, a_vars.key_for_iteration)
 				a_vars.forth
 			end

library/server/wsf/extension/filter/wsf_debug_filter.e

@@ -28,23 +28,19 @@ feature -- Basic operations
 			-- Execute the filter
 		local
 			s: STRING_8
+			dbg: WSF_DEBUG_OUTPUT
 		do
 			create s.make (2048)
-			if attached req.content_type as l_type then
+			create dbg.make
-				s.append ("[length=")
+			dbg.set_is_verbose (False)
-				s.append_natural_64 (req.content_length_value)
-				s.append_character (']')
-				s.append_character (' ')
-				s.append (l_type.debug_output)
-				s.append_character ('%N')
-			end
 
-			append_iterable_to ("Path parameters", req.path_parameters, s)
+			dbg.append_content_information_to (req, res, s)
-			append_iterable_to ("Query parameters", req.query_parameters, s)
+			dbg.append_path_parameters_to (req, res, s)
-			append_iterable_to ("Form parameters", req.form_parameters, s)
+			dbg.append_query_parameters_to (req, res, s)
+			dbg.append_path_parameters_to (req, res, s)
 
 			if not s.is_empty then
-				s.prepend ("**DEBUG**%N")
+				s.append ("**DEBUG**%N")
 				if attached output as o then
 					o.put_string (s)
 				else
@@ -84,8 +80,8 @@ feature -- Basic operations
 		end
 
 note
-	copyright: "Copyright (c) 1984-2013, Eiffel Software"
+	copyright: "2011-2014, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Colin Adams, Eiffel Software and others"
-	license: "GPL version 2 (see http://www.eiffel.com/licensing/gpl.txt)"
+	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
 	licensing_options: "http://www.eiffel.com/licensing"
 	copying: "[
 			This file is part of Eiffel Software's Eiffel Development Environment.

library/server/wsf/extension/handler/wsf_debug_handler.e

@@ -15,20 +15,6 @@ inherit
 
 	WSF_SELF_DOCUMENTED_HANDLER
 
-	SHARED_HTML_ENCODER
-
-	SHARED_WSF_PERCENT_ENCODER
-		rename
-			percent_encoder as url_encoder
-		export
-			{NONE} all
-		end
-
-	SHARED_EXECUTION_ENVIRONMENT
-		export
-			{NONE} all
-		end
-
 create
 	make,
 	make_hidden
@@ -64,103 +50,53 @@ feature -- Access
 		local
 			s: STRING_8
 			p: WSF_PAGE_RESPONSE
-			v: STRING_8
+			l_len: INTEGER
+			dbg: WSF_DEBUG_INFORMATION
 		do
 			create s.make (2048)
-			s.append ("**DEBUG**%N")
+			s.append ("= EWF DEBUG =")
-			req.set_raw_input_data_recorded (True)
+			s.append ("%N")
 
-			append_iterable_to ("Meta variables:", req.meta_variables, s)
+			create dbg.make
-			s.append_character ('%N')
+			dbg.append_information_to (req, res, s)
 
-			append_iterable_to ("Path parameters", req.path_parameters, s)
+			s.append ("= END =")
-			s.append_character ('%N')
+			s.append ("%N")
 
-			append_iterable_to ("Query parameters", req.query_parameters, s)
-			s.append_character ('%N')
-
-			append_iterable_to ("Form parameters", req.form_parameters, s)
-			s.append_character ('%N')
-
-			if attached req.content_type as l_type then
-				s.append ("Content: type=" + l_type.debug_output)
-				s.append (" length=")
-				s.append_natural_64 (req.content_length_value)
-				s.append_character ('%N')
-				create v.make (req.content_length_value.to_integer_32)
-				req.read_input_data_into (v)
-				across
-					v.split ('%N') as v_cursor
-				loop
-					s.append ("     |")
-					s.append (v_cursor.item)
-					s.append_character ('%N')
-				end
-			end
 
 			create p.make_with_body (s)
-			p.header.put_content_type_text_plain
+			if {PLATFORM}.is_windows and req.wgi_connector.name.is_case_insensitive_equal ("cgi") then
+					--| FIXME: the CGI connector add %R for any single %N character, so update the Content-Length accordingly.
+					-- Dirty hack to handle correctly CGI on Windows, since it seems "abc%N" will be sent as "abc%R%N"
+				l_len := 0
+				across s as ic loop
+					if ic.item = '%R' then
+						l_len := l_len + 1
+						ic.forth
+						if
+							not ic.after and then
+							ic.item = '%N'
+						then
+							l_len := l_len + 1
+						end
+					elseif ic.item = '%N' then
+						l_len := l_len + 2 -- %R will be added by the CGI connector...
+					else
+						l_len := l_len + 1
+					end
+				end
+			else
+				l_len := s.count
+			end
+
+			p.header.put_content_length (l_len)
+			p.header.put_content_type_utf_8_text_plain
 			res.send (p)
-
 		end
 
-feature {NONE} -- Implementation
-
-	append_iterable_to (a_title: READABLE_STRING_8; it: detachable ITERABLE [WSF_VALUE]; s: STRING_8)
-		local
-			n: INTEGER
-			t: READABLE_STRING_8
-			v: READABLE_STRING_8
-		do
-			s.append (a_title)
-			s.append_character (':')
-			if it /= Void then
-				across it as c loop
-					n := n + 1
-				end
-				if n = 0 then
-					s.append (" empty")
-					s.append_character ('%N')
-				else
-					s.append_character ('%N')
-					across
-						it as c
-					loop
-						s.append ("  - ")
-						s.append (c.item.url_encoded_name)
-						t := c.item.generating_type
-						if t.same_string ("WSF_STRING") then
-						else
-							s.append_character (' ')
-							s.append_character ('{')
-							s.append (t)
-							s.append_character ('}')
-						end
-						s.append_character ('=')
-						v := c.item.string_representation.as_string_8
-						if v.has ('%N') then
-							s.append_character ('%N')
-							across
-								v.split ('%N') as v_cursor
-							loop
-								s.append ("     |")
-								s.append (v_cursor.item)
-								s.append_character ('%N')
-							end
-						else
-							s.append (v)
-							s.append_character ('%N')
-						end
-					end
-				end
-			else
-				s.append (" none")
-				s.append_character ('%N')
-			end
-		end
 
 note
-	copyright: "2011-2013, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Colin Adams, Eiffel Software and others"
+	copyright: "2011-2014, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Colin Adams, Eiffel Software and others"
 	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
 	source: "[
 			Eiffel Software

library/server/wsf/extension/wsf_debug_information.e

@@ -0,0 +1,340 @@
+note
+	description: "[
+			Object used to output information from WSF_REQUEST objects
+		]"
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	WSF_DEBUG_INFORMATION
+
+inherit
+	ANY
+
+	SHARED_HTML_ENCODER
+
+	SHARED_WSF_PERCENT_ENCODER
+		rename
+			percent_encoder as url_encoder
+		export
+			{NONE} all
+		end
+
+	SHARED_EXECUTION_ENVIRONMENT
+		export
+			{NONE} all
+		end
+
+	WSF_REQUEST_EXPORTER
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make
+		do
+			is_verbose := True
+		end
+
+feature -- Settings
+
+	is_verbose: BOOLEAN
+			-- Has verbose output (default: True)?
+
+feature -- Settings change
+
+	set_is_verbose (b: BOOLEAN)
+			-- Set `is_verbose' to `b'.
+		do
+			is_verbose := b
+		end
+
+feature -- Execution
+
+	append_connector_informations_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			a_output.append ("Eiffel Web Server Gateway Interface (WGI):")
+			a_output.append (" implementation=%"")
+			a_output.append (req.wgi_implementation)
+			a_output.append ("%"")
+			a_output.append (" version=")
+			a_output.append (req.wgi_version)
+			a_output.append (" connector=%"")
+			a_output.append (req.wgi_connector.name)
+			a_output.append (" connector-version=")
+			a_output.append (req.wgi_connector.version)
+			a_output.append (eol)
+		end
+
+	append_cgi_variables_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			a_output.append ("CGI variables:")
+			a_output.append (eol)
+			a_output.append (req.cgi_variables.debug_output)
+			a_output.append (eol)
+			a_output.append (eol)
+		end
+
+	append_meta_variables_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			append_iterable_to ("Meta variables", req.meta_variables, a_output)
+			a_output.append (eol)
+		end
+
+	append_path_parameters_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			append_iterable_to ("Path parameters", req.path_parameters, a_output)
+			a_output.append (eol)
+		end
+
+	append_query_parameters_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			append_iterable_to ("Query parameters", req.query_parameters, a_output)
+			a_output.append (eol)
+		end
+
+	append_form_parameters_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			req.set_raw_input_data_recorded (True)
+			append_iterable_to ("Form parameters", req.form_parameters, a_output)
+			a_output.append (eol)
+		end
+
+	append_execution_variables_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			append_iterable_any_to ("Execution variables", req.execution_variables, a_output)
+			a_output.append (eol)
+		end
+
+	append_environment_variables_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			a_output.append ("Environment vars:")
+			a_output.append (eol)
+			across
+				(create {EXECUTION_ENVIRONMENT}).starting_environment_variables as ic
+			loop
+				a_output.append_character (' ')
+				a_output.append_character ('-')
+				a_output.append_string (ic.key)
+				a_output.append_character ('=')
+				a_output.append_string (ic.item)
+				a_output.append (eol)
+			end
+			a_output.append (eol)
+			a_output.append (eol)
+		end
+
+	append_all_variables_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			req.set_raw_input_data_recorded (True)
+
+			append_path_parameters_to (req, res, a_output)
+			append_query_parameters_to (req, res, a_output)
+			append_form_parameters_to (req, res, a_output)
+			append_meta_variables_to (req, res, a_output)
+			if is_verbose then
+				append_execution_variables_to (req, res, a_output)
+				append_environment_variables_to (req, res, a_output)
+			end
+		end
+
+	append_content_information_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		local
+			v: STRING_8
+		do
+			if attached req.content_type as l_type then
+				a_output.append ("Content: type=" + l_type.debug_output)
+				a_output.append (" length=")
+				a_output.append_natural_64 (req.content_length_value)
+				a_output.append (eol)
+				if is_verbose then
+					create v.make (req.content_length_value.to_integer_32)
+					req.set_raw_input_data_recorded (True)
+					req.read_input_data_into (v)
+					across
+						v.split ('%N') as v_cursor
+					loop
+						a_output.append ("     |")
+						a_output.append (v_cursor.item)
+						a_output.append (eol)
+					end
+					a_output.append (eol)
+				end
+			end
+		end
+
+	append_information_to (req: WSF_REQUEST; res: WSF_RESPONSE; a_output: STRING)
+		do
+			append_connector_informations_to (req, res, a_output)
+			a_output.append (eol)
+
+			append_all_variables_to (req, res, a_output)
+			a_output.append (eol)
+
+			append_content_information_to (req, res, a_output)
+			a_output.append (eol)
+		end
+
+feature {NONE} -- Implementation
+
+	iterable_count (a_iterable: ITERABLE [detachable ANY]): INTEGER
+		do
+			if attached {FINITE [detachable ANY]} a_iterable as a_finite then
+				Result := a_finite.count
+			else
+				across a_iterable as ic loop
+					Result := Result + 1
+				end
+			end
+		end
+
+	append_iterable_any_to (a_title: READABLE_STRING_8; it: detachable TABLE_ITERABLE [detachable ANY, READABLE_STRING_GENERAL]; s: STRING_8)
+		local
+			n: INTEGER
+			v: READABLE_STRING_8
+			utf: UTF_CONVERTER
+		do
+			if is_verbose then
+				s.append (a_title)
+				s.append_character (':')
+			end
+			if it /= Void then
+				n := iterable_count (it)
+				if n = 0 then
+					if is_verbose then
+						s.append (" empty")
+						s.append (eol)
+					end
+				else
+					s.append (eol)
+					across
+						it as c
+					loop
+						s.append ("  - ")
+						s.append (utf.escaped_utf_32_string_to_utf_8_string_8 (c.key))
+						s.append_character (' ')
+						if attached c.item as l_item then
+							s.append_character ('{')
+							s.append (l_item.generating_type)
+							s.append_character ('}')
+
+							s.append_character (' ')
+							s.append_character ('=')
+							s.append_character (' ')
+							if attached {READABLE_STRING_GENERAL} c.item as l_string then
+								v := "%"" + utf.escaped_utf_32_string_to_utf_8_string_8 (l_string) + "%""
+							elseif attached {DEBUG_OUTPUT} c.item as l_dbg_output then
+								v := utf.escaped_utf_32_string_to_utf_8_string_8 (l_dbg_output.debug_output)
+							else
+								v := "..."
+							end
+							if v.has ('%N') then
+								s.append (eol)
+								across
+									v.split ('%N') as v_cursor
+								loop
+									s.append ("     |")
+									s.append (v_cursor.item)
+									s.append (eol)
+								end
+							else
+								s.append (v)
+								s.append (eol)
+							end
+						else
+							s.append_character ('=')
+							s.append ("Void")
+							s.append (eol)
+						end
+					end
+				end
+			else
+				if is_verbose then
+					s.append (" none")
+					s.append (eol)
+				end
+			end
+		end
+
+	append_iterable_to (a_title: READABLE_STRING_8; it: detachable ITERABLE [WSF_VALUE]; a_output: STRING_8)
+		local
+			n: INTEGER
+			t: READABLE_STRING_8
+			v: READABLE_STRING_8
+			s: READABLE_STRING_GENERAL
+			utf: UTF_CONVERTER
+		do
+			if is_verbose then
+				a_output.append (a_title)
+				a_output.append_character (':')
+			end
+			if it /= Void then
+				n := iterable_count (it)
+				if n = 0 then
+					if is_verbose then
+						a_output.append (" empty")
+						a_output.append (eol)
+					end
+				else
+					a_output.append (eol)
+					across
+						it as c
+					loop
+						a_output.append ("  - ")
+						a_output.append (c.item.url_encoded_name)
+						t := c.item.generating_type
+						if t.same_string ("WSF_STRING") then
+						else
+							a_output.append_character (' ')
+							a_output.append_character ('{')
+							a_output.append (t)
+							a_output.append_character ('}')
+						end
+						a_output.append_character ('=')
+						s := c.item.string_representation
+						if s.is_valid_as_string_8 then
+							v := s.as_string_8
+						else
+							v := utf.escaped_utf_32_string_to_utf_8_string_8 (s)
+						end
+						if v.has ('%N') then
+							a_output.append (eol)
+							across
+								v.split ('%N') as v_cursor
+							loop
+								a_output.append ("     |")
+								a_output.append (v_cursor.item)
+								a_output.append (eol)
+							end
+						else
+							a_output.append (v)
+							a_output.append (eol)
+						end
+					end
+				end
+			else
+				if is_verbose then
+					a_output.append (" none")
+					a_output.append (eol)
+				end
+			end
+		end
+
+feature -- Constants
+
+	eol: STRING = "%N"
+
+invariant
+
+note
+	copyright: "2011-2014, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Colin Adams, Eiffel Software and others"
+	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
+	source: "[
+			Eiffel Software
+			5949 Hollister Ave., Goleta, CA 93117 USA
+			Telephone 805-685-1006, Fax 805-685-6869
+			Website http://www.eiffel.com
+			Customer support http://support.eiffel.com
+		]"
+end

library/server/wsf/src/request/wsf_value.e

@@ -71,6 +71,7 @@ feature -- Query
 	string_representation: STRING_32
 			-- String representation of Current
 			-- if possible
+			-- note: unicode value.
 		deferred
 		end
 
@@ -127,7 +128,7 @@ feature -- Visitor
 		end
 
 note
-	copyright: "2011-2013, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Eiffel Software and others"
+	copyright: "2011-2014, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Colin Adams, Eiffel Software and others"
 	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
 	source: "[
 			Eiffel Software

library/server/wsf/src/wsf_request.e

@@ -87,6 +87,7 @@ feature {NONE} -- Initialization
 		local
 			s8: detachable READABLE_STRING_8
 			req: WGI_REQUEST
+			utf: UTF_CONVERTER
 		do
 			init_mime_handlers
 			req := wgi_request
@@ -110,7 +111,7 @@ feature {NONE} -- Initialization
 			request_method := req.request_method
 
 				--| PATH_INFO
-			unicode_path_info := url_decoded_string (req.path_info)
+			path_info := utf.utf_8_string_8_to_string_32 (req.path_info)
 
 				--| Here one can set its own environment entries if needed
 			if meta_variable ({WSF_META_NAMES}.request_time) = Void then
@@ -132,9 +133,19 @@ feature {NONE} -- Initialization
 			end
 		end
 
+feature {WSF_REQUEST_EXPORTER} -- Restricted Access		
+
 	wgi_request: WGI_REQUEST
 			-- Associated WGI request
 
+	cgi_variables: WGI_REQUEST_CGI_VARIABLES
+			-- Object containing the CGI variables
+			--| mainly for debugging purpose.
+			--| note: a new instance is created on each call!
+		do
+			Result := wgi_request.cgi_variables
+		end
+
 feature -- Destroy
 
 	destroy
@@ -158,7 +169,8 @@ feature -- Destroy
 			internal_url_base := Void
 			form_parameters_table.wipe_out
 			mime_handlers := Void
-			unicode_path_info := empty_string_32
+			path_info := empty_string_32
+			internal_percent_encoded_path_info := Void
 			path_parameters_source := Void
 			path_parameters_table := Void
 			raw_input_data := Void
@@ -604,6 +616,12 @@ feature -- Helpers: global variables
 
 feature -- Execution variables
 
+	execution_variables: TABLE_ITERABLE [detachable ANY, READABLE_STRING_GENERAL]
+			-- Execution variables values.
+		do
+			Result := execution_variables_table
+		end
+
 	has_execution_variable (a_name: READABLE_STRING_GENERAL): BOOLEAN
 			-- Has execution variable related to `a_name'?
 		require
@@ -821,24 +839,52 @@ feature -- Access: CGI meta parameters - 1.1
 		end
 
 	percent_encoded_path_info: READABLE_STRING_8
-			-- Non decoded PATH_INFO value from CGI.
+			-- Percent encoded PATH_INFO value from CGI.
 			-- See `path_info' for the related percent decoded value.
 			--| This value should be used by component dealing only with ASCII path
-		obsolete
+			--| this value is not always available, so it requires to be computed.
-			"Use directly `path_info' which is not decoded [June/2014]"
+		local
+			l_result: like internal_percent_encoded_path_info
+			r: READABLE_STRING_8
+			i: INTEGER
 		do
-			Result := path_info
+			l_result := internal_percent_encoded_path_info
+			if l_result = Void then
+				r := request_uri
+				i := r.index_of ('?', 1)
+				if i > 0 then
+					l_result := r.substring (1, i - 1)
+				else
+					l_result := r.string
+				end
+				if attached script_name as s then
+					if l_result.starts_with (s) then
+						l_result := l_result.substring (s.count + 1, l_result.count)
+					end
+				end
+				internal_percent_encoded_path_info := l_result
+			end
+			Result := l_result
 		end
 
-	path_info: READABLE_STRING_8
+	utf_8_path_info: READABLE_STRING_8
+			-- UTF-8 encoded value for PATH_INFO.
+			-- See `path_info' for extended description.
+		do
+			Result := wgi_request.path_info
+		end
+
+	path_info: READABLE_STRING_32
 			-- The PATH_INFO metavariable specifies a path to be interpreted
 			-- by the CGI script. It identifies the resource or sub-resource
 			-- to be returned by the CGI script, and it is derived from the
 			-- portion of the URI path following the script name but
-			-- preceding any query data. The syntax and semantics are similar
+			-- preceding any query data.
-			-- to a decoded HTTP URL 'path' token (defined in RFC 2396 [4]),
+			-- Unlike a URI path, the PATH_INFO is not URL-encoded, and cannot
-			-- with the exception that a PATH_INFO of "/" represents a single
+   			-- contain path-segment parameters.
-			-- void path segment.
+			-- The syntax and semantics are similar to a decoded HTTP URL 'path' token
+			-- (defined in RFC 2396 [4]), with the exception that a PATH_INFO of "/"
+			-- represents a single void path segment.
 			--
 			--  PATH_INFO = "" | ( "/" path )
 			--  path      = segment *( "/" segment )
@@ -858,13 +904,9 @@ feature -- Access: CGI meta parameters - 1.1
 			-- The PATH_INFO value is case-sensitive, and the server MUST
 			-- preserve the case of the PATH_INFO element of the URI when
 			-- making it available to scripts.
-		do
+			--
-			Result := wgi_request.path_info
+			-- Note: this is the unicode version of PATH_INFO, for utf-8 version
-		end
+			-- please use `utf_8_path_info', which is the real CGI value of PATH_INFO.
-
-	unicode_path_info: READABLE_STRING_32
-			-- Percent decoded version of `path_info'
-			-- See `path_info' to get the original non decoded path info.	
 
 	path_translated: detachable READABLE_STRING_8
 			-- PATH_TRANSLATED is derived by taking any path-info component
@@ -909,19 +951,12 @@ feature -- Access: CGI meta parameters - 1.1
 			--
 			-- Servers SHOULD provide this metavariable to scripts if and
 			-- only if the wgi_request URI includes a path-info component.
+			--
+			-- note: it is UTF_8 encoded.
 		do
 			Result := wgi_request.path_translated
 		end
 
-	unicode_path_translated: detachable READABLE_STRING_32
-			-- Percent decoded version of `path_translated'
-			-- See `path_translated' to get the original non decoded path info.	
-		do
-			if attached path_translated as s then
-				Result := url_decoded_string (s)
-			end
-		end
-
 	query_string: READABLE_STRING_8
 			-- A URL-encoded string; the <query> part of the Script-URI. (See
 			-- section 3.2.)
@@ -1863,6 +1898,9 @@ feature {NONE} -- Implementation: URL Utility
 	internal_url_base: detachable STRING
 			-- URL base of potential script
 
+	internal_percent_encoded_path_info: detachable like percent_encoded_path_info
+			-- Cache value of `percent_encoded_path_info'
+
 feature -- Element change
 
 	set_raw_input_data_recorded (b: BOOLEAN)

library/text/encoder/src/percent_encoder.e

@@ -208,8 +208,15 @@ feature {NONE} -- Implementation: character encoding
 feature -- Percent decoding
 
 	percent_decoded_string (v: READABLE_STRING_GENERAL): STRING_32
-			-- Return the percent decoded string equivalent to the percent-encoded string `v'
+			-- Return the percent decoded unicode string equivalent to the percent-encoded string `v'
-			--| Note that is `a_result' is a STRING_8, any Unicode character will be kept as UTF-8
+		do
+			create Result.make (v.count)
+			append_percent_decoded_string_to (v, Result)
+		end
+
+	percent_decoded_utf_8_string (v: READABLE_STRING_GENERAL): STRING_8
+			-- Return the percent decoded UTF-8 string equivalent to the percent-encoded string `v'
+			--| Note that any Unicode character will be kept as UTF-8
 		do
 			create Result.make (v.count)
 			append_percent_decoded_string_to (v, Result)

library/text/encoder/src/url_encoder.e

@@ -23,7 +23,8 @@ inherit
 	PERCENT_ENCODER
 		rename
 			percent_encoded_string as general_encoded_string,
-			percent_decoded_string as general_decoded_string
+			percent_decoded_string as general_decoded_string,
+			percent_decoded_utf_8_string as general_decoded_utf_8_string
 		end
 
 feature -- Access
@@ -49,6 +50,12 @@ feature -- Decoder
 			Result := general_decoded_string (v)
 		end
 
+	decoded_utf_8_string (v: READABLE_STRING_8): STRING_8
+			-- The URL-encoded equivalent of the given string
+		do
+			Result := general_decoded_utf_8_string (v)
+		end
+
 note
 	copyright: "Copyright (c) 2011-2014, Eiffel Software and others"
 	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"