Updated CMS with Login Module.

-- The module handle basic_auth (at the moment).
     -- Handle login, logout, register user, activate/reactivate an account, password recovery.
     -- Send notification emails.

CMS Updates
     -- Added a new service: email.
     -- Updated Basic Auth Module to handle logout based on the browser type.
     -- Updated persistence layer to save and remove and query activation token and password token.
     -- Updated CMS_USER to handle status {active, not_active, trashed}.
     -- Updated MySQL scripts to be in sync with SQLite scripts

src/service/email/email_service.e

@@ -0,0 +1,102 @@
+note
+	description: "Basic Email Service"
+	date: "$Date: 2015-04-30 05:45:25 -0300 (ju. 30 de abr. de 2015) $"
+	revision: "$Revision: 97218 $"
+
+class
+	EMAIL_SERVICE
+
+inherit
+
+	SHARED_ERROR
+	SHARED_LOGGER
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make (a_params: like parameters)
+			-- Create instance of {EMAIL_SERVICE} with smtp_server `a_params.smtp_server'.
+			-- Using `a_params.admin_email' as admin email.
+		do
+			parameters := a_params
+			initialize
+		end
+
+	initialize
+			-- Initialize service.
+		local
+			l_address_factory: INET_ADDRESS_FACTORY
+		do
+			admin_email := parameters.admin_email
+
+				-- Get local host name needed in creation of SMTP_PROTOCOL.
+			create l_address_factory
+			create smtp_protocol.make (parameters.smtp_server, l_address_factory.create_localhost.host_name)
+			set_successful
+		end
+
+	parameters: EMAIL_SERVICE_PARAMETERS
+			-- Associated parameters.
+
+	admin_email: IMMUTABLE_STRING_8
+			-- Site admin's email.
+
+	smtp_protocol: SMTP_PROTOCOL
+			-- SMTP protocol.
+
+feature -- Basic Operations
+
+	send_internal_email (a_content: READABLE_STRING_GENERAL)
+		do
+			send_message (admin_email, admin_email, "Notification Contact", a_content)
+		end
+
+	send_email_internal_server_error (a_content: READABLE_STRING_GENERAL)
+		do
+			send_message (admin_email, admin_email, "Internal Server Error", a_content)
+		end
+
+	send_message (a_from_address, a_to_address: READABLE_STRING_8; a_subjet: READABLE_STRING_GENERAL; a_content: READABLE_STRING_GENERAL)
+		local
+			l_email: EMAIL
+			utf: UTF_CONVERTER
+		do
+			write_debug_log (generator + ".send_message: [from:" + a_from_address + ", to:" + a_to_address + ", subject:" + a_subjet + ", content:" + a_content)
+			create l_email.make_with_entry (a_from_address, a_to_address)
+			l_email.set_message (utf.escaped_utf_32_string_to_utf_8_string_8 (a_content))
+			l_email.add_header_entry ({EMAIL_CONSTANTS}.H_subject, utf.escaped_utf_32_string_to_utf_8_string_8 (a_subjet))
+			l_email.add_header_entry ("MIME-Version:", "1.0")
+			l_email.add_header_entry ("Content-Type", "text/html; charset=utf-8")
+			send_email (l_email)
+		end
+
+feature {NONE} -- Implementation
+
+	send_email (a_email: EMAIL)
+			-- Send the email represented by `a_email'.
+		local
+			l_retried: BOOLEAN
+		do
+			if not l_retried then
+				write_information_log (generator + ".send_email Process send email.")
+				smtp_protocol.initiate_protocol
+				smtp_protocol.transfer (a_email)
+				smtp_protocol.close_protocol
+				write_information_log (generator + ".send_email Email sent.")
+				if smtp_protocol.error then
+					set_last_error ("smtp_protocol reported an error", generator + ".send_email")
+				else
+					set_successful
+				end
+			else
+				write_error_log (generator + ".send_email Email not send " + last_error_message )
+			end
+		rescue
+			set_last_error_from_exception (generator + ".send_email")
+			l_retried := True
+			retry
+		end
+
+end

src/service/email/email_service_parameters.e

@@ -0,0 +1,20 @@
+note
+	description: "Basic Email Service customized for cms site"
+	author: ""
+	date: "$Date: 2015-01-16 07:17:14 -0300 (vi. 16 de ene. de 2015) $"
+	revision: "$Revision: 96467 $"
+
+deferred class
+	EMAIL_SERVICE_PARAMETERS
+
+feature	-- Access
+
+	smtp_server: IMMUTABLE_STRING_8
+		deferred
+		end
+
+	admin_email: IMMUTABLE_STRING_8
+		deferred
+		end
+
+end

src/service/user/cms_user_api.e

@@ -29,6 +29,24 @@ feature -- Access
 			Result := storage.user_by_name (a_username)
 		end
 
+	user_by_email (a_email: READABLE_STRING_32): detachable CMS_USER
+			-- User by email `a_email', if any.
+		do
+			Result := storage.user_by_email (a_email)
+		end
+
+	user_by_activation_token (a_token: READABLE_STRING_32): detachable CMS_USER
+			-- User by activation token `a_token'.
+		do
+			Result := storage.user_by_activation_token (a_token)
+		end
+
+	user_by_password_token (a_token: READABLE_STRING_32): detachable CMS_USER
+			-- User by password token `a_token'.
+		do
+			Result := storage.user_by_password_token (a_token)
+		end
+
 feature -- Status report
 
 	is_valid_credential (a_auth_login, a_auth_password: READABLE_STRING_32): BOOLEAN
@@ -133,4 +151,43 @@ feature -- Change User
 			storage.update_user (a_user)
 		end
 
+feature -- User Activation
+
+	new_activation (a_token: READABLE_STRING_32; a_id: INTEGER_64)
+			-- Save activation token `a_token', for the user with the id `a_id'.
+		do
+			storage.save_activation (a_token, a_id)
+		end
+
+	remove_activation (a_token: READABLE_STRING_32)
+			-- Remove activation token `a_token', from the storage.
+		do
+			storage.remove_activation (a_token)
+		end
+
+feature -- User Password Recovery
+
+	new_password (a_token: READABLE_STRING_32; a_id: INTEGER_64)
+			-- Save password token `a_token', for the user with the id `a_id'.
+		do
+			storage.save_password (a_token, a_id)
+		end
+
+	remove_password (a_token: READABLE_STRING_32)
+			-- Remove password token `a_token', from the storage.
+		do
+			storage.remove_password (a_token)
+		end
+
+feature -- User status
+
+	not_active: INTEGER = 0
+			-- The user is not active.
+
+	active: INTEGER = 1
+			-- The user is active
+
+	Trashed: INTEGER = -1
+			-- The user is trashed (soft delete), ready to be deleted/destroyed from storage.
+
 end