Fixing bad library paths (using Fabian's local paths).

Fixed response building for /upload/
Added /upload/{filename} .
Added CMS_FILE_UPLOAD_API.

The storage/database part is untouched (and thus not implemented).

modules/file_upload/cms_file.e

@@ -0,0 +1,69 @@
+note
+	description: "Interface representing any files under `{CMS_API}.files_location' ."
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	CMS_FILE
+
+create
+	make
+
+feature {NONE} -- Initializaion
+
+	make (a_relative_path: PATH; a_api: CMS_API)
+		do
+			cms_api := a_api
+			location := a_relative_path
+		end
+
+	cms_api: CMS_API
+
+feature -- Access
+
+	filename: STRING_32
+			-- File name of Current file.
+		local
+			p: PATH
+		do
+			p := location
+			if attached p.entry as e then
+				Result := e.name
+			else
+				Result := p.name
+			end
+		end
+
+	location: PATH
+			-- Path relative the `CMS_API.files_location'.
+
+	owner: detachable CMS_USER
+			-- Optional owner.
+
+feature -- Status report
+
+	is_directory: BOOLEAN
+		local
+			d: DIRECTORY
+		do
+			create d.make_with_path (cms_api.files_location.extended_path (location))
+			Result := d.exists
+		end
+
+	is_file: BOOLEAN
+		local
+			f: RAW_FILE
+		do
+			create f.make_with_path (cms_api.files_location.extended_path (location))
+			Result := f.exists
+		end
+
+feature -- Element change
+
+	set_owner (u: detachable CMS_USER)
+			-- Set `owner' to `u'.
+		do
+			owner := u
+		end
+
+end