Moved library/src to src

src/modules/basic_auth/basic_auth_module.e

@@ -0,0 +1,73 @@
+note
+	description: "This module allows the use of HTTP Basic Authentication to restrict access by looking up users in the given providers."
+	date: "$Date: 2014-11-13 16:23:47 +0100 (jeu., 13 nov. 2014) $"
+	revision: "$Revision: 96085 $"
+
+class
+	BASIC_AUTH_MODULE
+
+inherit
+
+	CMS_MODULE
+		redefine
+			filters
+		end
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make
+		do
+			name := "basic auth"
+			version := "1.0"
+			description := "Service to manage basic authentication"
+			package := "core"
+		end
+
+feature -- Access: router
+
+	router (a_api: CMS_API): WSF_ROUTER
+			-- Node router.
+		do
+			create Result.make (2)
+			configure_api_login (a_api, Result)
+			configure_api_logoff (a_api, Result)
+		end
+
+feature -- Access: filter
+
+	filters (a_api: CMS_API): detachable LIST [WSF_FILTER]
+			-- Possibly list of Filter's module.
+		do
+			create {ARRAYED_LIST [WSF_FILTER]} Result.make (2)
+			Result.extend (create {CORS_FILTER})
+			Result.extend (create {BASIC_AUTH_FILTER}.make (a_api))
+		end
+
+feature {NONE} -- Implementation: routes
+
+	configure_api_login (api: CMS_API; a_router: WSF_ROUTER)
+		local
+			l_bal_handler: BASIC_AUTH_LOGIN_HANDLER
+			l_methods: WSF_REQUEST_METHODS
+		do
+			create l_bal_handler.make (api)
+			create l_methods
+			l_methods.enable_get
+			a_router.handle_with_request_methods ("/basic_auth_login", l_bal_handler, l_methods)
+		end
+
+	configure_api_logoff (api: CMS_API; a_router: WSF_ROUTER)
+		local
+			l_bal_handler: BASIC_AUTH_LOGOFF_HANDLER
+			l_methods: WSF_REQUEST_METHODS
+		do
+			create l_bal_handler.make (api)
+			create l_methods
+			l_methods.enable_get
+			a_router.handle_with_request_methods ("/basic_auth_logoff", l_bal_handler, l_methods)
+		end
+
+end

src/modules/basic_auth/filter/basic_auth_filter.e

@@ -0,0 +1,57 @@
+note
+	description: "Processes a HTTP request's BASIC authorization headers, putting the result into the execution variable user."
+	date: "$Date: 2014-11-13 16:23:47 +0100 (jeu., 13 nov. 2014) $"
+	revision: "$Revision: 96085 $"
+
+class
+	BASIC_AUTH_FILTER
+
+inherit
+
+	WSF_URI_TEMPLATE_HANDLER
+	CMS_HANDLER
+	WSF_FILTER
+
+create
+	make
+
+feature -- Basic operations
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute the filter.
+		local
+			l_auth: HTTP_AUTHORIZATION
+		do
+			log.write_debug (generator + ".execute " )
+			create l_auth.make (req.http_authorization)
+			if attached req.raw_header_data as l_raw_data then
+			   log.write_debug (generator + ".execute " + l_raw_data )
+			end
+				-- A valid user
+			if (attached l_auth.type as l_auth_type and then l_auth_type.is_case_insensitive_equal_general ("basic")) and then
+				attached l_auth.login as l_auth_login and then attached l_auth.password as l_auth_password then
+				if api.is_valid_credential (l_auth_login, l_auth_password) then
+					if attached api.user_by_name (l_auth_login) as l_user then
+						debug ("refactor_fixme")
+							fixme ("Maybe we need to store in the credentials in a shared context SECURITY_CONTEXT")
+							-- req.set_execution_variable ("security_content", create SECURITY_CONTEXT.make (l_user))
+							-- other authentication filters (OpenID, etc) should implement the same approach.
+						end
+						req.set_execution_variable ("user", l_user)
+						execute_next (req, res)
+					else
+						debug ("refactor_fixme")
+							to_implement ("Internal server error")
+						end
+					end
+				else
+					log.write_error (generator + ".execute login_valid failed for: " + l_auth_login )
+					execute_next (req, res)
+				end
+			else
+				log.write_error (generator + ".execute Not valid")
+				execute_next (req, res)
+			end
+		end
+
+end

src/modules/basic_auth/filter/cors_filter.e

@@ -0,0 +1,28 @@
+note
+	description: "CORS filter"
+	date: "$Date: 2014-11-13 16:23:47 +0100 (jeu., 13 nov. 2014) $"
+	revision: "$Revision: 96085 $"
+
+class
+	CORS_FILTER
+
+inherit
+
+	WSF_FILTER
+
+feature -- Basic operations
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute the filter.
+		local
+			l_header: HTTP_HEADER
+		do
+			create l_header.make
+--			l_header.add_header_key_value ("Access-Control-Allow-Origin", "localhost")
+			l_header.add_header_key_value ("Access-Control-Allow-Headers", "*")
+			l_header.add_header_key_value ("Access-Control-Allow-Methods", "*")
+			l_header.add_header_key_value ("Access-Control-Allow-Credentials", "true")
+			res.put_header_lines (l_header)
+			execute_next (req, res)
+		end
+end

src/modules/basic_auth/handler/basic_auth_login_handler.e

@@ -0,0 +1,60 @@
+note
+	description: "Summary description for {BASIC_AUTH_LOGIN_HANDLER}."
+	date: "$Date: 2014-11-13 16:23:47 +0100 (jeu., 13 nov. 2014) $"
+	revision: "$Revision: 96085 $"
+
+class
+	BASIC_AUTH_LOGIN_HANDLER
+
+inherit
+	CMS_HANDLER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_FILTER
+
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler.
+		do
+			execute_methods (req, res)
+			execute_next (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler.
+		do
+			execute_methods (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			log.write_information(generator + ".do_get Processing basic auth login")
+			if attached {STRING_32} current_user_name (req) as l_user then
+				(create {CMS_GENERIC_RESPONSE}).new_response_redirect (req, res, req.absolute_script_url("/"))
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_authenticate (req, res)
+			end
+		end
+
+
+end

src/modules/basic_auth/handler/basic_auth_logoff_handler.e

@@ -0,0 +1,59 @@
+note
+	description: "Summary description for {BASIC_AUTH_LOGOFF_HANDLER}."
+	date: "$Date: 2014-11-13 16:23:47 +0100 (jeu., 13 nov. 2014) $"
+	revision: "$Revision: 96085 $"
+
+class
+	BASIC_AUTH_LOGOFF_HANDLER
+
+inherit
+	CMS_HANDLER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler.
+		do
+			execute_methods (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler.
+		do
+			execute_methods (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+			log.write_information(generator + ".do_get Processing basic auth logoff")
+			if attached req.query_parameter ("prompt") as l_prompt then
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			else
+				create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+				l_page.set_status_code ({HTTP_STATUS_CODE}.unauthorized)
+				l_page.execute
+			end
+		end
+
+end

src/modules/cms_debug_module.e

@@ -0,0 +1,140 @@
+note
+	description: "Summary description for {CMS_DEBUG_MODULE}."
+	date: "$Date: 2014-12-18 16:47:20 +0100 (jeu., 18 déc. 2014) $"
+	revision: "$Revision: 96384 $"
+
+class
+	CMS_DEBUG_MODULE
+
+inherit
+	CMS_MODULE
+		redefine
+			register_hooks
+		end
+
+--	CMS_HOOK_BLOCK
+
+	CMS_HOOK_AUTO_REGISTER
+
+	SHARED_EXECUTION_ENVIRONMENT
+		export
+			{NONE} all
+		end
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make
+		do
+			name := "debug"
+			version := "1.0"
+			description := "Debug"
+			package := "cms"
+		end
+
+feature -- Router
+
+	router (a_api: CMS_API): WSF_ROUTER
+			-- Router configuration.
+		do
+			create Result.make (1)
+			Result.handle ("/debug/", create {WSF_URI_TEMPLATE_AGENT_HANDLER}.make (agent handle_debug (a_api, ?, ?)))
+		end
+
+feature -- Hooks configuration
+
+	register_hooks (a_response: CMS_RESPONSE)
+			-- Module hooks configuration.
+		do
+			auto_subscribe_to_hooks (a_response)
+--			a_response.subscribe_to_block_hook (Current)
+		end
+
+feature -- Hooks
+
+--	block_list: ITERABLE [like {CMS_BLOCK}.name]
+--		do
+--			Result := <<"debug-info">>
+--		end
+
+--	get_block_view (a_block_id: READABLE_STRING_8; a_response: CMS_RESPONSE)
+--		local
+--			b: CMS_CONTENT_BLOCK
+--		do
+--			create b.make ("debug-info", "Debug", "... ", a_response.formats.plain_text)
+--			a_response.add_block (b, Void)
+--		end
+
+feature -- Handler		
+
+	handle_debug (api: CMS_API; req: WSF_REQUEST; res: WSF_RESPONSE)
+		local
+			r: CMS_RESPONSE
+			s: STRING
+		do
+			if req.is_get_request_method then
+				create {GENERIC_VIEW_CMS_RESPONSE} r.make (req, res, api)
+				r.set_title ("DEBUG")
+
+				create s.make_empty
+				append_info_to ("Name", api.setup.site_name, r, s)
+				append_info_to ("Url", api.setup.site_url, r, s)
+
+				if attached api.setup.layout.cms_config_ini_path as l_loc then
+					s.append ("<hr/>")
+					append_info_to ("Configuration file", l_loc.name, r, s)
+				end
+
+				s.append ("<hr/>")
+
+				append_info_to ("Current dir", execution_environment.current_working_path.utf_8_name, r, s)
+--				append_info_to ("Base url", cms.base_url, r, s)
+--				append_info_to ("Script url", cms.script_url, r, s)
+				s.append ("<hr/>")
+				append_info_to ("Site dir", api.setup.layout.path.utf_8_name, r, s)
+				append_info_to ("Www dir", api.setup.layout.www_path.utf_8_name, r, s)
+				append_info_to ("Assets dir", api.setup.layout.assets_path.utf_8_name, r, s)
+				append_info_to ("Config dir", api.setup.layout.config_path.utf_8_name, r, s)
+				s.append ("<hr/>")
+				append_info_to ("Theme", api.setup.theme_name, r, s)
+				append_info_to ("Theme location", api.setup.themes_location.utf_8_name, r, s)
+				s.append ("<hr/>")
+--				append_info_to ("Files location", api...files_location.utf_8_name, r, s)
+--				s.append ("<hr/>")
+
+				append_info_to ("Url", r.url ("/", Void), r, s)
+--				if attached r.user as u then
+--					append_info_to ("User", u.name, r, s)
+--					append_info_to ("User url", r.user_url (u), r, s)
+--				end
+
+				r.set_main_content (s)
+			else
+				create {NOT_FOUND_ERROR_CMS_RESPONSE} r.make (req, res, api)
+			end
+			r.execute
+		end
+
+	append_info_to (n: READABLE_STRING_8; v: detachable READABLE_STRING_GENERAL; r: CMS_RESPONSE; t: STRING)
+		do
+			t.append ("<li>")
+			t.append ("<strong>" + n + "</strong>: ")
+			if v /= Void then
+				t.append (r.html_encoded (v))
+			end
+			t.append ("</li>")
+		end
+
+note
+	copyright: "Copyright (c) 1984-2013, Eiffel Software and others"
+	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
+	source: "[
+			Eiffel Software
+			5949 Hollister Ave., Goleta, CA 93117 USA
+			Telephone 805-685-1006, Fax 805-685-6869
+			Website http://www.eiffel.com
+			Customer support http://support.eiffel.com
+		]"
+end

src/modules/cms_module.e

@@ -0,0 +1,85 @@
+note
+	description: "Describe module features that adds one or more features to your web site."
+	date: "$Date: 2014-11-13 16:23:47 +0100 (jeu., 13 nov. 2014) $"
+	revision: "$Revision: 96085 $"
+
+deferred class
+	CMS_MODULE
+
+inherit
+
+	REFACTORING_HELPER
+
+feature -- Access
+
+	is_enabled: BOOLEAN
+			-- Is the module enabled?
+
+	name: STRING
+			-- Name of the module.
+
+	description: STRING
+			-- Description of the module.
+
+	package: STRING
+			--
+
+	version: STRING
+			-- Version od the module?
+
+feature -- Router
+
+	router (a_api: CMS_API): WSF_ROUTER
+			-- Router configuration.
+		require
+			is_enabled: is_enabled
+		deferred
+		end
+
+feature -- Hooks configuration
+
+	register_hooks (a_response: CMS_RESPONSE)
+			-- Module hooks configuration.
+		require
+			is_enabled: is_enabled
+		do
+		end
+
+feature -- Filter
+
+	filters (a_api: CMS_API): detachable LIST [WSF_FILTER]
+			-- Optional list of filter for Current module.
+		require
+			is_enabled: is_enabled
+		do
+		end
+
+feature -- Settings
+
+	enable
+			-- enable the module.
+		do
+			is_enabled := True
+		ensure
+			module_enabled: is_enabled
+		end
+
+	disable
+			-- disable the module.
+		do
+			is_enabled := False
+		ensure
+			module_disbaled: not is_enabled
+		end
+
+feature -- Hooks
+
+	help_text (a_path: STRING): STRING
+		do
+			debug ("refactor_fixme")
+				to_implement ("Add the corresponing implementation.")
+			end
+			create Result.make_empty
+		end
+
+end

src/modules/cms_module_collection.e

@@ -0,0 +1,64 @@
+note
+	description: "Summary description for {CMS_MODULE_COLLECTION}."
+	author: ""
+	date: "$Date: 2014-11-13 16:23:47 +0100 (jeu., 13 nov. 2014) $"
+	revision: "$Revision: 96085 $"
+
+class
+	CMS_MODULE_COLLECTION
+
+inherit
+	ITERABLE [CMS_MODULE]
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make (nb: INTEGER)
+		do
+			create modules.make (nb)
+		end
+
+feature -- Access
+
+	new_cursor: INDEXABLE_ITERATION_CURSOR [CMS_MODULE]
+			-- <Precursor>
+		do
+			Result := modules.new_cursor
+		end
+
+feature -- Status report
+
+	has (a_module: CMS_MODULE): BOOLEAN
+			-- Has `a_module'?
+		do
+			Result := modules.has (a_module)
+		end
+
+	count: INTEGER
+			-- Number of modules.
+		do
+			Result := modules.count
+		end
+
+feature -- Element change
+
+	extend (a_module: CMS_MODULE)
+			-- Add module
+		do
+			modules.force (a_module)
+		end
+
+	remove (a_module: CMS_MODULE)
+			-- Remove module
+		do
+			modules.prune_all (a_module)
+		end
+
+feature {NONE} -- Implementation		
+
+	modules: ARRAYED_LIST [CMS_MODULE]
+			-- List of available modules.
+
+end

src/modules/node/handler/node_content_handler.e

@@ -0,0 +1,171 @@
+note
+	description: "Summary description for {NEW_CONTENT_HANDLER}."
+	date: "$Date: 2015-01-27 19:15:02 +0100 (mar., 27 janv. 2015) $"
+	revision: "$Revision: 96542 $"
+
+class
+	NODE_CONTENT_HANDLER
+
+inherit
+
+	CMS_HANDLER
+
+	WSF_FILTER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_URI_TEMPLATE_HANDLER
+		rename
+			execute as uri_template_execute,
+			new_mapping as new_uri_template_mapping
+		select
+			new_uri_template_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get,
+			do_post,
+			do_put
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+			execute_next (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+	uri_template_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+			if attached current_user_name (req) then
+					-- Existing node
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached {CMS_NODE} api.node (l_id.integer_value) as l_node then
+						create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+						l_page.add_variable (l_node.content, "node_content")
+						l_page.add_variable (l_id.value, "id")
+						l_page.execute
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+
+	do_post (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			if attached current_user_name (req) then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached {CMS_NODE} api.node (l_id.integer_value) as l_node then
+						if attached {WSF_STRING} req.form_parameter ("method") as l_method then
+							if l_method.is_case_insensitive_equal ("PUT") then
+								do_put (req, res)
+							else
+								(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+							end
+						end
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+	do_put (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			u_node: CMS_NODE
+		do
+			to_implement ("Check if user has permissions")
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached {CMS_NODE} api.node (l_id.integer_value) as l_node then
+						u_node := extract_data_form (req)
+						u_node.set_id (l_id.value.to_integer_64)
+						api.update_node_content (l_user.id, u_node.id, u_node.content)
+						(create {CMS_GENERIC_RESPONSE}).new_response_redirect (req, res, req.absolute_script_url (""))
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+feature -- Error
+
+	do_error (req: WSF_REQUEST; res: WSF_RESPONSE; a_id: WSF_STRING)
+			-- Handling error.
+		local
+			l_page: CMS_RESPONSE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (req.absolute_script_url (req.path_info), "request")
+			if a_id.is_integer then
+					-- resource not found
+				l_page.add_variable ("404", "code")
+				l_page.set_status_code (404)
+			else
+					-- bad request
+				l_page.add_variable ("400", "code")
+				l_page.set_status_code (400)
+			end
+			l_page.execute
+		end
+
+
+feature -- {NONE} Form data
+
+
+	extract_data_form (req: WSF_REQUEST): CMS_NODE
+			-- Extract request form data and build a object
+			-- Node
+		do
+			create Result.make ("", "", "")
+			if attached {WSF_STRING}req.form_parameter ("content") as l_content then
+				Result.set_content (l_content.value)
+			end
+		end
+
+end

src/modules/node/handler/node_handler.e

@@ -0,0 +1,226 @@
+note
+	description: "Summary description for {NODE_HANDLER}."
+	date: "$Date: 2015-01-27 19:15:02 +0100 (mar., 27 janv. 2015) $"
+	revision: "$Revision: 96542 $"
+
+class
+	NODE_HANDLER
+
+inherit
+	CMS_HANDLER
+
+	WSF_FILTER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_URI_TEMPLATE_HANDLER
+		rename
+			execute as uri_template_execute,
+			new_mapping as new_uri_template_mapping
+		select
+			new_uri_template_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get,
+			do_post,
+			do_put,
+			do_delete
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+			execute_next (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+	uri_template_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+				-- Existing node
+			if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+				if
+					l_id.is_integer and then
+					attached api.node (l_id.value.to_integer_64) as l_node
+				then
+					create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+					l_page.add_variable (l_node, "node")
+					l_page.execute
+				else
+					do_error (req, res, l_id)
+				end
+			else
+					-- Factory
+				new_node (req, res)
+			end
+		end
+
+	do_post (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			u_node: CMS_NODE
+		do
+			to_implement ("Check user permissions!!!")
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if
+						l_id.is_integer and then
+						attached {CMS_NODE} api.node (l_id.value.to_integer_64) as l_node
+					then
+						if attached {WSF_STRING} req.form_parameter ("method") as l_method then
+							if l_method.is_case_insensitive_equal ("DELETE") then
+								do_delete (req, res)
+							elseif l_method.is_case_insensitive_equal ("PUT") then
+								do_put (req, res)
+							else
+								(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+							end
+						end
+					else
+						do_error (req, res, l_id)
+					end
+				else
+						-- New node
+					create u_node.make ("", "", "")
+					update_node_from_data_form (req, u_node)
+					u_node.set_author (l_user)
+					api.new_node (u_node)
+					(create {CMS_GENERIC_RESPONSE}).new_response_redirect (req, res, req.absolute_script_url (""))
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+	do_put (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if
+						l_id.is_integer and then
+						attached api.node (l_id.value.to_integer_64) as l_node
+					then
+						update_node_from_data_form (req, l_node)
+						l_node.set_author (l_user)
+						api.update_node (l_node)
+						(create {CMS_GENERIC_RESPONSE}).new_response_redirect (req, res, req.absolute_script_url (""))
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+	do_delete (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			if attached current_user_name (req) then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if
+						l_id.is_integer and then
+						attached api.node (l_id.integer_value) as l_node
+					then
+						api.delete_node (l_node)
+						(create {CMS_GENERIC_RESPONSE}).new_response_redirect (req, res, req.absolute_script_url (""))
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+feature -- Error
+
+	do_error (req: WSF_REQUEST; res: WSF_RESPONSE; a_id: WSF_STRING)
+			-- Handling error.
+		local
+			l_page: CMS_RESPONSE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (req.absolute_script_url (req.path_info), "request")
+			if a_id.is_integer then
+					-- resource not found
+				l_page.add_variable ("404", "code")
+				l_page.set_status_code (404)
+			else
+					-- bad request
+				l_page.add_variable ("400", "code")
+				l_page.set_status_code (400)
+			end
+			l_page.execute
+		end
+
+feature {NONE} -- Node
+
+	new_node (req: WSF_REQUEST; res: WSF_RESPONSE)
+		local
+			l_page: CMS_RESPONSE
+		do
+			if attached current_user_name (req) then
+				create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+				l_page.add_variable (setup.is_html, "html")
+				l_page.add_variable (setup.is_web, "web")
+				l_page.execute
+
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+feature -- {NONE} Form data
+
+	update_node_from_data_form (req: WSF_REQUEST; a_node: CMS_NODE)
+			-- Extract request form data and build a object
+			-- Node
+		do
+			if attached {WSF_STRING} req.form_parameter ("title") as l_title then
+				a_node.set_title (l_title.value)
+			end
+			if attached {WSF_STRING} req.form_parameter ("summary") as l_summary then
+				a_node.set_summary (l_summary.value)
+			end
+			if attached {WSF_STRING} req.form_parameter ("content") as l_content then
+				a_node.set_content (l_content.value)
+			end
+		end
+
+end

src/modules/node/handler/node_summary_handler.e

@@ -0,0 +1,171 @@
+note
+	description: "Summary description for {NODE_SUMMARY_HANDLER}."
+	date: "$Date: 2015-01-27 19:15:02 +0100 (mar., 27 janv. 2015) $"
+	revision: "$Revision: 96542 $"
+
+class
+	NODE_SUMMARY_HANDLER
+
+inherit
+	CMS_HANDLER
+
+	WSF_FILTER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_URI_TEMPLATE_HANDLER
+		rename
+			execute as uri_template_execute,
+			new_mapping as new_uri_template_mapping
+		select
+			new_uri_template_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get,
+			do_post,
+			do_put
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+			execute_next (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+	uri_template_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+			if attached current_user_name (req) then
+					-- Existing node
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached {CMS_NODE} api.node (l_id.integer_value) as l_node then
+						create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+						l_page.add_variable (l_id.value, "id")
+						l_page.add_variable (l_node.summary, "node_summary")
+						l_page.execute
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+
+	do_post (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			if attached current_user_name (req) then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached {CMS_NODE} api.node (l_id.integer_value) as l_node then
+						if attached {WSF_STRING} req.form_parameter ("method") as l_method then
+							if l_method.is_case_insensitive_equal ("PUT") then
+								do_put (req, res)
+							else
+								(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+							end
+						end
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+	do_put (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			u_node: CMS_NODE
+		do
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached {CMS_NODE} api.node (l_id.integer_value) as l_node then
+						u_node := extract_data_form (req)
+						u_node.set_id (l_id.value.to_integer_64)
+						api.update_node_summary (l_user.id,u_node.id, u_node.summary)
+						(create {CMS_GENERIC_RESPONSE}).new_response_redirect (req, res, req.absolute_script_url (""))
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+feature -- Error
+
+
+	do_error (req: WSF_REQUEST; res: WSF_RESPONSE; a_id: WSF_STRING)
+			-- Handling error.
+		local
+			l_page: CMS_RESPONSE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (req.absolute_script_url (req.path_info), "request")
+			if a_id.is_integer then
+					-- resource not found
+				l_page.add_variable ("404", "code")
+				l_page.set_status_code (404)
+			else
+					-- bad request
+				l_page.add_variable ("400", "code")
+				l_page.set_status_code (400)
+			end
+			l_page.execute
+		end
+
+
+feature -- {NONE} Form data
+
+
+	extract_data_form (req: WSF_REQUEST): CMS_NODE
+			-- Extract request form data and build a object
+			-- Node
+		do
+			create Result.make ("", "", "")
+			if attached {WSF_STRING}req.form_parameter ("summary") as l_summary then
+				Result.set_summary (l_summary.value)
+			end
+		end
+
+end

src/modules/node/handler/node_title_handler.e

@@ -0,0 +1,169 @@
+note
+	description: "Summary description for {NODE_TITLE_HANDLER}."
+	date: "$Date: 2015-01-27 19:15:02 +0100 (mar., 27 janv. 2015) $"
+	revision: "$Revision: 96542 $"
+
+class
+	NODE_TITLE_HANDLER
+
+inherit
+	CMS_HANDLER
+
+	WSF_FILTER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_URI_TEMPLATE_HANDLER
+		rename
+			execute as uri_template_execute,
+			new_mapping as new_uri_template_mapping
+		select
+			new_uri_template_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get,
+			do_post,
+			do_put
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+			execute_next (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+	uri_template_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+			if attached current_user_name (req) as l_user then
+					-- Existing node
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached {CMS_NODE} api.node (l_id.integer_value) as l_node then
+						create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+						l_page.add_variable (l_node.title, "node_title")
+						l_page.add_variable (l_id.value, "id")
+						l_page.execute
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+	do_post (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			if attached current_user_name (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached {CMS_NODE} api.node (l_id.integer_value) as l_node then
+						if attached {WSF_STRING} req.form_parameter ("method") as l_method then
+							if l_method.is_case_insensitive_equal ("PUT") then
+								do_put (req, res)
+							else
+								(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+							end
+						end
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+	do_put (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			u_node: CMS_NODE
+		do
+			to_implement ("Check if user has permissions")
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached {CMS_NODE} api.node (l_id.integer_value) as l_node then
+						u_node := extract_data_form (req)
+						u_node.set_id (l_id.value.to_integer_64)
+						api.update_node_title (l_user.id,u_node.id, u_node.title)
+						(create {CMS_GENERIC_RESPONSE}).new_response_redirect (req, res, req.absolute_script_url (""))
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				(create {CMS_GENERIC_RESPONSE}).new_response_unauthorized (req, res)
+			end
+		end
+
+feature -- Error
+
+	do_error (req: WSF_REQUEST; res: WSF_RESPONSE; a_id: WSF_STRING)
+			-- Handling error.
+		local
+			l_page: CMS_RESPONSE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (req.absolute_script_url (req.path_info), "request")
+			if a_id.is_integer then
+					-- resource not found
+				l_page.add_variable ("404", "code")
+				l_page.set_status_code (404)
+			else
+					-- bad request
+				l_page.add_variable ("400", "code")
+				l_page.set_status_code (400)
+			end
+			l_page.execute
+		end
+
+
+feature -- {NONE} Form data
+
+	extract_data_form (req: WSF_REQUEST): CMS_NODE
+			-- Extract request form data and build a object
+			-- Node
+		do
+			create Result.make ("", "", "")
+			if attached {WSF_STRING} req.form_parameter ("title") as l_title then
+				Result.set_title (l_title.value)
+			end
+		end
+
+end

src/modules/node/handler/nodes_handler.e

@@ -0,0 +1,59 @@
+note
+	description: "Summary description for {NODES_HANDLER}."
+	date: "$Date: 2014-11-13 16:23:47 +0100 (jeu., 13 nov. 2014) $"
+	revision: "$Revision: 96085 $"
+
+class
+	NODES_HANDLER
+
+inherit
+	CMS_HANDLER
+
+	WSF_FILTER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+			execute_next (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+				-- At the moment the template is hardcoded, but we can
+				-- get them from the configuration file and load them into
+				-- the setup class.
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (api.nodes, "nodes")
+			l_page.execute
+		end
+end

src/modules/node/node_module.e

@@ -0,0 +1,200 @@
+note
+	description: "CMS module that bring support for NODE management."
+	date: "$Date: 2015-01-27 19:15:02 +0100 (mar., 27 janv. 2015) $"
+	revision: "$Revision: 96542 $"
+
+class
+	NODE_MODULE
+
+inherit
+
+	CMS_MODULE
+		redefine
+			register_hooks
+		end
+
+	CMS_HOOK_MENU_SYSTEM_ALTER
+
+	CMS_HOOK_BLOCK
+
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make (a_setup: CMS_SETUP)
+			-- Create Current module, disabled by default.
+		do
+			name := "node"
+			version := "1.0"
+			description := "Service to manage content based on 'node'"
+			package := "core"
+			config := a_setup
+		end
+
+	config: CMS_SETUP
+			-- Node configuration.
+
+feature -- Access: router
+
+	router (a_api: CMS_API): WSF_ROUTER
+			-- Node router.
+		do
+			create Result.make (5)
+			configure_api_node (a_api, Result)
+			configure_api_nodes (a_api, Result)
+			configure_api_node_title (a_api, Result)
+			configure_api_node_summary (a_api, Result)
+			configure_api_node_content (a_api, Result)
+		end
+
+feature {NONE} -- Implementation: routes
+
+	configure_api_node (api: CMS_API; a_router: WSF_ROUTER)
+		local
+			l_node_handler: NODE_HANDLER
+			l_methods: WSF_REQUEST_METHODS
+		do
+			create l_node_handler.make (api)
+			create l_methods
+			l_methods.enable_get
+			l_methods.enable_post
+			l_methods.enable_put
+			a_router.handle_with_request_methods ("/node", l_node_handler, l_methods)
+
+			create l_node_handler.make (api)
+			create l_methods
+			l_methods.enable_get
+			l_methods.enable_post
+			l_methods.enable_put
+			l_methods.enable_delete
+			a_router.handle_with_request_methods ("/node/{id}", l_node_handler, l_methods)
+			a_router.handle_with_request_methods ("/nodes/", create {WSF_URI_AGENT_HANDLER}.make (agent do_get_nodes (?,?, api)), a_router.methods_get)
+		end
+
+	configure_api_nodes (api: CMS_API; a_router: WSF_ROUTER)
+		local
+			l_nodes_handler: NODES_HANDLER
+			l_methods: WSF_REQUEST_METHODS
+		do
+			create l_nodes_handler.make (api)
+			create l_methods
+			l_methods.enable_get
+			a_router.handle_with_request_methods ("/nodes", l_nodes_handler, l_methods)
+		end
+
+	configure_api_node_summary (api: CMS_API; a_router: WSF_ROUTER)
+		local
+			l_report_handler: NODE_SUMMARY_HANDLER
+			l_methods: WSF_REQUEST_METHODS
+		do
+			create l_report_handler.make (api)
+			create l_methods
+			l_methods.enable_get
+			l_methods.enable_post
+			l_methods.enable_put
+			a_router.handle_with_request_methods ("/node/{id}/summary", l_report_handler, l_methods)
+		end
+
+	configure_api_node_title (api: CMS_API; a_router: WSF_ROUTER)
+		local
+			l_report_handler: NODE_TITLE_HANDLER
+			l_methods: WSF_REQUEST_METHODS
+		do
+			create l_report_handler.make (api)
+			create l_methods
+			l_methods.enable_get
+			l_methods.enable_post
+			l_methods.enable_put
+			a_router.handle_with_request_methods ("/node/{id}/title", l_report_handler, l_methods)
+		end
+
+	configure_api_node_content (api: CMS_API; a_router: WSF_ROUTER)
+		local
+			l_report_handler: NODE_CONTENT_HANDLER
+			l_methods: WSF_REQUEST_METHODS
+		do
+			create l_report_handler.make (api)
+			create l_methods
+			l_methods.enable_get
+			l_methods.enable_post
+			l_methods.enable_put
+			a_router.handle_with_request_methods ("/node/{id}/content", l_report_handler, l_methods)
+		end
+
+feature -- Hooks
+
+	register_hooks (a_response: CMS_RESPONSE)
+		do
+			a_response.subscribe_to_menu_system_alter_hook (Current)
+			a_response.subscribe_to_block_hook (Current)
+		end
+
+	block_list: ITERABLE [like {CMS_BLOCK}.name]
+		do
+			Result := <<"node-info">>
+		end
+
+	get_block_view (a_block_id: READABLE_STRING_8; a_response: CMS_RESPONSE)
+		local
+--			b: CMS_CONTENT_BLOCK
+		do
+--			create b.make (a_block_id, "Block::node", "This is a block test", Void)
+--			a_response.add_block (b, "sidebar_second")
+		end
+
+	menu_system_alter (a_menu_system: CMS_MENU_SYSTEM; a_response: CMS_RESPONSE)
+		local
+			lnk: CMS_LOCAL_LINK
+--			perms: detachable ARRAYED_LIST [READABLE_STRING_8]
+		do
+			create lnk.make ("List of nodes", a_response.url ("/nodes", Void))
+			a_menu_system.primary_menu.extend (lnk)
+		end
+
+feature -- Handler
+
+	do_get_nodes (req: WSF_REQUEST; res: WSF_RESPONSE; a_api: CMS_API)
+		local
+			r: CMS_RESPONSE
+			s: STRING
+			l_user: CMS_USER
+			l_node: CMS_NODE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} r.make (req, res, a_api)
+
+			if attached a_api.user_by_name ("foo") as u then
+				l_user := u
+			else
+				create l_user.make ("foo")
+				l_user.set_password ("foobar#")
+				l_user.set_email ("test@example.com")
+				a_api.new_user (l_user)
+			end
+			if a_api.nodes_count = 0 then
+				create l_node.make ({STRING_32} "This is a content", {STRING_32} "And a summary", {STRING_32} "Nice title")
+				l_node.set_author (l_user)
+				a_api.new_node (l_node)
+			end
+
+			create s.make_from_string ("<p>Nodes:</p>")
+			if attached a_api.nodes as lst then
+				across
+					lst as ic
+				loop
+					s.append ("<li>")
+					s.append (a_api.html_encoded (ic.item.title))
+					s.append (" (")
+					s.append (ic.item.id.out)
+					s.append (")")
+					s.append ("</li>%N")
+				end
+			end
+
+			r.set_main_content (s)
+			r.add_block (create {CMS_CONTENT_BLOCK}.make ("nodes_warning", Void, "/nodes/ is not yet fully implemented<br/>", Void), "highlighted")
+			r.execute
+		end
+
+end