Moved src/modules under modules cluster.

modules/node/handler/cms_content_type_webform_manager.e

@@ -0,0 +1,33 @@
+note
+	description: "[
+				Html builder for content type `content_type'.
+				This is used to build webform and html output for a specific node, or node content type.
+			]"
+	date: "$Date$"
+	revision: "$Revision$"
+
+deferred class
+	CMS_CONTENT_TYPE_WEBFORM_MANAGER
+
+inherit
+	CMS_API_ACCESS
+
+feature {NONE} -- Initialization
+
+	make (a_type: like content_type)
+		do
+			content_type := a_type
+		end
+
+feature -- Access
+
+	content_type: CMS_CONTENT_TYPE
+			-- Associated content type.
+
+	name: READABLE_STRING_8
+			-- Associated content type name.
+		do
+			Result := content_type.name
+		end
+
+end

modules/node/handler/cms_node_handler.e

@@ -0,0 +1,16 @@
+note
+	description: "Summary description for {CMS_NODE_HANDLER}."
+	author: ""
+	date: "$Date: 2015-02-13 13:08:13 +0100 (ven., 13 févr. 2015) $"
+	revision: "$Revision: 96616 $"
+
+deferred class
+	CMS_NODE_HANDLER
+
+inherit
+	CMS_MODULE_HANDLER [CMS_NODE_API]
+		rename
+			module_api as node_api
+		end
+
+end

modules/node/handler/cms_node_type_webform_manager.e

@@ -0,0 +1,199 @@
+note
+	description: "Summary description for {CMS_NODE_TYPE_WEBFORM_MANAGER}."
+	date: "$Date$"
+	revision: "$Revision$"
+
+deferred class
+	CMS_NODE_TYPE_WEBFORM_MANAGER [G -> CMS_NODE]
+
+inherit
+	CMS_NODE_TYPE_WEBFORM_MANAGER_I [G]
+
+feature -- Forms ...		
+
+	populate_form (response: NODE_RESPONSE; f: CMS_FORM; a_node: detachable CMS_NODE)
+		local
+			ti: WSF_FORM_TEXT_INPUT
+			fset: WSF_FORM_FIELD_SET
+			ta: WSF_FORM_TEXTAREA
+			tselect: WSF_FORM_SELECT
+			opt: WSF_FORM_SELECT_OPTION
+		do
+			create ti.make ("title")
+			ti.set_label ("Title")
+			ti.set_size (70)
+			if a_node /= Void then
+				ti.set_text_value (a_node.title)
+			end
+			ti.set_is_required (True)
+			f.extend (ti)
+
+			f.extend_html_text ("<br/>")
+
+			create ta.make ("body")
+			ta.set_rows (10)
+			ta.set_cols (70)
+			if a_node /= Void then
+				ta.set_text_value (a_node.content)
+			end
+--			ta.set_label ("Body")
+			ta.set_description ("This is the main content")
+			ta.set_is_required (False)
+
+			create fset.make
+			fset.set_legend ("Body")
+			fset.extend (ta)
+
+			fset.extend_html_text ("<br/>")
+
+			create tselect.make ("format")
+			tselect.set_label ("Body's format")
+			tselect.set_is_required (True)
+			across
+				 content_type.available_formats as c
+			loop
+				create opt.make (c.item.name, c.item.title)
+				if attached c.item.html_help as f_help then
+					opt.set_description ("<ul>" + f_help + "</ul>")
+				end
+				tselect.add_option (opt)
+			end
+			if a_node /= Void and then attached a_node.format as l_format then
+				tselect.set_text_by_value (l_format)
+			end
+
+			fset.extend (tselect)
+
+			f.extend (fset)
+		end
+
+	update_node	(response: NODE_RESPONSE; fd: WSF_FORM_DATA; a_node: CMS_NODE)
+		local
+			b: detachable READABLE_STRING_8
+			f: detachable CONTENT_FORMAT
+		do
+			if attached fd.integer_item ("id") as l_id and then l_id > 0 then
+				check a_node.id = l_id end
+			end
+			if attached fd.string_item ("title") as l_title then
+				a_node.set_title (l_title)
+			end
+
+			if attached fd.string_item ("body") as l_body then
+				b := l_body
+			end
+			if attached fd.string_item ("format") as s_format and then attached response.api.format (s_format) as f_format then
+				f := f_format
+			elseif a_node /= Void and then attached a_node.format as s_format and then attached response.api.format (s_format) as f_format then
+				f := f_format
+			else
+				f := response.api.formats.default_format
+			end
+			if b /= Void then
+				a_node.set_content (b, Void, f.name) -- FIXME: summary
+			end
+		end
+
+	new_node (response: NODE_RESPONSE; fd: WSF_FORM_DATA; a_node: detachable CMS_NODE): G
+			-- <Precursor>
+		local
+			b: detachable READABLE_STRING_8
+			f: detachable CONTENT_FORMAT
+			l_node: detachable like new_node
+		do
+			if attached {like new_node} a_node as l_arg_node then
+				l_node := l_arg_node
+			else
+				l_node := content_type.new_node (a_node)
+			end
+			if attached fd.integer_item ("id") as l_id and then l_id > 0 then
+				if l_node /= Void then
+					check l_node.id = l_id end
+				else
+					if attached {like new_node} response.node_api.node (l_id) as n then
+						l_node := n
+					else
+						-- FIXME: Error
+					end
+				end
+			end
+			if attached fd.string_item ("title") as l_title then
+				if l_node = Void then
+					l_node := content_type.new_node (Void)
+					l_node.set_title (l_title)
+				else
+					l_node.set_title (l_title)
+				end
+			else
+				if l_node = Void then
+					l_node := content_type.new_node_with_title ("...", Void)
+				end
+			end
+			l_node.set_author (response.user)
+
+			if attached fd.string_item ("body") as l_body then
+				b := l_body
+			end
+			if attached fd.string_item ("format") as s_format and then attached response.api.format (s_format) as f_format then
+				f := f_format
+			elseif a_node /= Void and then attached a_node.format as s_format and then attached response.api.format (s_format) as f_format then
+				f := f_format
+			else
+				f := response.api.formats.default_format
+			end
+			if b /= Void then
+				l_node.set_content (b, Void, f.name)
+			end
+			Result := l_node
+		end
+
+feature -- Output
+
+	append_html_output_to (a_node: CMS_NODE; a_response: NODE_RESPONSE)
+			-- <Precursor>
+		local
+			lnk: CMS_LOCAL_LINK
+			hdate: HTTP_DATE
+			s: STRING
+			node_api: CMS_NODE_API
+		do
+			node_api := a_response.node_api
+
+			a_response.add_variable (a_node, "node")
+			create lnk.make ("View", node_api.node_path (a_node))
+			lnk.set_weight (1)
+			a_response.add_to_primary_tabs (lnk)
+			create lnk.make ("Edit", node_api.node_path (a_node) + "/edit")
+			lnk.set_weight (2)
+			a_response.add_to_primary_tabs (lnk)
+
+			create s.make_empty
+			s.append ("<div class=%"info%"> ")
+			if attached a_node.author as l_author then
+				s.append (" by ")
+				s.append (l_author.name)
+			end
+			if attached a_node.modification_date as l_modified then
+				s.append (" (modified: ")
+				create hdate.make_from_date_time (l_modified)
+				s.append (hdate.yyyy_mmm_dd_string)
+				s.append (")")
+			end
+			s.append ("</div>")
+			if attached a_node.content as l_content then
+				s.append ("<p class=%"content%">")
+				if attached node_api.cms_api.format (a_node.format) as f then
+					s.append (f.formatted_output (l_content))
+				else
+					s.append (node_api.cms_api.formats.default_format.formatted_output (l_content))
+				end
+
+				s.append ("</p>")
+			end
+
+			a_response.set_title (a_node.title)
+			a_response.set_main_content (s)
+		end
+
+end
+

modules/node/handler/cms_node_type_webform_manager_i.e

@@ -0,0 +1,67 @@
+note
+	description: "[
+				Html builder for content type `content_type'.
+				This is used to build webform and html output for a specific node, or node content type.
+			]"
+	date: "$Date$"
+	revision: "$Revision$"
+
+deferred class
+	CMS_NODE_TYPE_WEBFORM_MANAGER_I [G -> CMS_NODE]
+
+inherit
+	CMS_CONTENT_TYPE_WEBFORM_MANAGER
+		redefine
+			content_type
+		end
+
+feature -- Access
+
+	content_type: CMS_NODE_TYPE [G]
+			-- Associated content type.
+
+feature -- Query			
+
+	has_valid_node_type (a_node: CMS_NODE): BOOLEAN
+			-- Accept `a_node' for Current operations.
+		do
+			Result := attached {like new_node} a_node
+		end
+
+feature -- Forms ...		
+
+	populate_form (response: NODE_RESPONSE; a_form: WSF_FORM; a_node: detachable CMS_NODE)
+			-- Fill the web form `a_form' with data from `a_node' if set.
+		require
+			a_node = Void or else has_valid_node_type (a_node)
+		deferred
+		end
+
+feature -- Node ...		
+
+	new_node (response: NODE_RESPONSE; a_form_data: WSF_FORM_DATA; a_node: detachable CMS_NODE): G
+			-- New typed node with data from `a_form_data', and eventually data from `a_node' if set.
+		require
+			a_node = Void or else has_valid_node_type (a_node)
+		deferred
+			--| Possible implementation:
+			--| Result := content_type.new_node (a_node)
+		end
+
+	update_node (response: NODE_RESPONSE; a_form_data: WSF_FORM_DATA; a_node: CMS_NODE)
+			-- Update node `a_node' with data from `a_form_data'.
+		require
+			has_valid_node_type (a_node)
+		deferred
+		end
+
+feature -- Output
+
+	append_html_output_to (a_node: CMS_NODE; a_response: NODE_RESPONSE)
+			-- Append an html representation of `a_node' to response `a_response'.
+		require
+			has_valid_node_type (a_node)
+		deferred
+		end
+
+end

modules/node/handler/cms_page_node_type_webform_manager.e

@@ -0,0 +1,185 @@
+note
+	description: "Summary description for {CMS_PAGE_NODE_TYPE_WEBFORM_MANAGER}."
+	author: ""
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	CMS_PAGE_NODE_TYPE_WEBFORM_MANAGER
+
+inherit
+	CMS_NODE_TYPE_WEBFORM_MANAGER [CMS_PAGE]
+		redefine
+			content_type,
+			append_html_output_to
+		end
+
+create
+	make
+
+feature -- Access
+
+	content_type: CMS_PAGE_NODE_TYPE
+			-- Associated content type.	
+
+feature -- Forms ...		
+
+--	fill_edit_form (response: NODE_RESPONSE; f: CMS_FORM; a_node: detachable CMS_NODE)
+--		local
+--			ti: WSF_FORM_TEXT_INPUT
+--			fset: WSF_FORM_FIELD_SET
+--			ta: WSF_FORM_TEXTAREA
+--			tselect: WSF_FORM_SELECT
+--			opt: WSF_FORM_SELECT_OPTION
+--		do
+--			create ti.make ("title")
+--			ti.set_label ("Title")
+--			ti.set_size (70)
+--			if a_node /= Void then
+--				ti.set_text_value (a_node.title)
+--			end
+--			ti.set_is_required (True)
+--			f.extend (ti)
+
+--			f.extend_html_text ("<br/>")
+
+--			create ta.make ("body")
+--			ta.set_rows (10)
+--			ta.set_cols (70)
+--			if a_node /= Void then
+--				ta.set_text_value (a_node.content)
+--			end
+----			ta.set_label ("Body")
+--			ta.set_description ("This is the main content")
+--			ta.set_is_required (False)
+
+--			create fset.make
+--			fset.set_legend ("Body")
+--			fset.extend (ta)
+
+--			fset.extend_html_text ("<br/>")
+
+--			create tselect.make ("format")
+--			tselect.set_label ("Body's format")
+--			tselect.set_is_required (True)
+--			across
+--				 content_type.available_formats as c
+--			loop
+--				create opt.make (c.item.name, c.item.title)
+--				if attached c.item.html_help as f_help then
+--					opt.set_description ("<ul>" + f_help + "</ul>")
+--				end
+--				tselect.add_option (opt)
+--			end
+--			if a_node /= Void and then attached a_node.format as l_format then
+--				tselect.set_text_by_value (l_format)
+--			end
+
+--			fset.extend (tselect)
+
+--			f.extend (fset)
+
+--		end
+
+--	change_node	(response: NODE_RESPONSE; fd: WSF_FORM_DATA; a_node: like new_node)
+--		local
+--			b: detachable READABLE_STRING_8
+--			f: detachable CONTENT_FORMAT
+--		do
+--			if attached fd.integer_item ("id") as l_id and then l_id > 0 then
+--				check a_node.id = l_id end
+--			end
+--			if attached fd.string_item ("title") as l_title then
+--				a_node.set_title (l_title)
+--			end
+
+--			if attached fd.string_item ("body") as l_body then
+--				b := l_body
+--			end
+--			if attached fd.string_item ("format") as s_format and then attached response.api.format (s_format) as f_format then
+--				f := f_format
+--			elseif a_node /= Void and then attached a_node.format as s_format and then attached response.api.format (s_format) as f_format then
+--				f := f_format
+--			else
+--				f := response.api.formats.default_format
+--			end
+--			if b /= Void then
+--				a_node.set_content (b, Void, f.name) -- FIXME: summary
+--			end
+--		end
+
+--	new_node (response: NODE_RESPONSE; fd: WSF_FORM_DATA; a_node: detachable like new_node): CMS_PAGE
+--			-- <Precursor>
+--		local
+--			b: detachable READABLE_STRING_8
+--			f: detachable CONTENT_FORMAT
+--			l_node: detachable like new_node
+--		do
+--			l_node := a_node
+--			if attached fd.integer_item ("id") as l_id and then l_id > 0 then
+--				if l_node /= Void then
+--					check l_node.id = l_id end
+--				else
+--					if attached {like new_node} response.node_api.node (l_id) as n then
+--						l_node := n
+--					else
+--						-- FIXME: Error
+--					end
+--				end
+--			end
+--			if attached fd.string_item ("title") as l_title then
+--				if l_node = Void then
+--					l_node := content_type.new_node (Void)
+--					l_node.set_title (l_title)
+--				else
+--					l_node.set_title (l_title)
+--				end
+--			else
+--				if l_node = Void then
+--					l_node := content_type.new_node_with_title ("...", Void)
+--				end
+--			end
+--			l_node.set_author (response.user)
+
+--			if attached fd.string_item ("body") as l_body then
+--				b := l_body
+--			end
+--			if attached fd.string_item ("format") as s_format and then attached response.api.format (s_format) as f_format then
+--				f := f_format
+--			elseif a_node /= Void and then attached a_node.format as s_format and then attached response.api.format (s_format) as f_format then
+--				f := f_format
+--			else
+--				f := response.api.formats.default_format
+--			end
+--			if b /= Void then
+--				l_node.set_content (b, Void, f.name)
+--			end
+--			Result := l_node
+--		end
+
+feature -- Output
+
+	append_html_output_to (a_node: CMS_NODE; a_response: NODE_RESPONSE)
+			-- <Precursor>
+		local
+			s: STRING
+		do
+			Precursor (a_node, a_response)
+			if attached a_response.main_content as l_main_content then
+				s := l_main_content
+			else
+				create s.make_empty
+			end
+
+			if attached {CMS_PAGE} a_node as l_node_page then
+				if attached l_node_page.parent as l_parent_node then
+					s.append ("<div>Parent page is ")
+					s.append (a_response.link (l_parent_node.title + " (#" + l_parent_node.id.out + ")", a_response.node_api.node_path (l_parent_node), Void))
+					s.append ("</div>")
+				end
+			end
+
+			a_response.set_main_content (s)
+		end
+
+end

modules/node/handler/experimental/node_content_handler.e

@@ -0,0 +1,167 @@
+note
+	description: "Summary description for {NEW_CONTENT_HANDLER}."
+	date: "$Date: 2015-02-13 13:08:13 +0100 (ven., 13 févr. 2015) $"
+	revision: "$Revision: 96616 $"
+
+class
+	NODE_CONTENT_HANDLER
+
+inherit
+	CMS_NODE_HANDLER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_URI_TEMPLATE_HANDLER
+		rename
+			execute as uri_template_execute,
+			new_mapping as new_uri_template_mapping
+		select
+			new_uri_template_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get,
+			do_post,
+			do_put
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+	uri_template_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+			if attached current_user_name (req) then
+					-- Existing node
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached node_api.node (l_id.integer_value) as l_node then
+						create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+						l_page.add_variable (l_node.content, "node_content")
+						l_page.add_variable (l_id.value, "id")
+						l_page.execute
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+
+	do_post (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			if attached current_user_name (req) then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached node_api.node (l_id.integer_value) as l_node then
+						if attached {WSF_STRING} req.form_parameter ("method") as l_method then
+							if l_method.is_case_insensitive_equal ("PUT") then
+								do_put (req, res)
+							else
+								(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+							end
+						end
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+	do_put (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			u_node: CMS_NODE
+		do
+			to_implement ("Check if user has permissions")
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached node_api.node (l_id.integer_value) as l_node then
+						u_node := extract_data_form (req)
+						u_node.set_id (l_id.value.to_integer_64)
+						node_api.update_node_content (l_user.id, u_node.id, u_node.content)
+						redirect_to (req.absolute_script_url (""), res)
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+feature -- Error
+
+	do_error (req: WSF_REQUEST; res: WSF_RESPONSE; a_id: WSF_STRING)
+			-- Handling error.
+		local
+			l_page: CMS_RESPONSE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (req.absolute_script_url (req.path_info), "request")
+			if a_id.is_integer then
+					-- resource not found
+				l_page.add_variable ("404", "code")
+				l_page.set_status_code (404)
+			else
+					-- bad request
+				l_page.add_variable ("400", "code")
+				l_page.set_status_code (400)
+			end
+			l_page.execute
+		end
+
+
+feature -- {NONE} Form data
+
+
+	extract_data_form (req: WSF_REQUEST): CMS_NODE
+			-- Extract request form data and build a object
+			-- Node
+		do
+			create Result.make ("", "", "")
+			if attached {WSF_STRING}req.form_parameter ("content") as l_content then
+				Result.set_content (l_content.value)
+			end
+		end
+
+end

modules/node/handler/experimental/node_resource_handler.e

@@ -0,0 +1,240 @@
+note
+	description: "Node handler for the API."
+	date: "$Date: 2015-02-13 13:08:13 +0100 (ven., 13 févr. 2015) $"
+	revision: "$Revision: 96616 $"
+
+class
+	NODE_RESOURCE_HANDLER
+
+inherit
+	CMS_NODE_HANDLER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_URI_TEMPLATE_HANDLER
+		rename
+			execute as uri_template_execute,
+			new_mapping as new_uri_template_mapping
+		select
+			new_uri_template_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get,
+			do_post,
+			do_put,
+			do_delete
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+	uri_template_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+				-- Existing node
+			if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+				if
+					l_id.is_integer and then
+					attached node_api.node (l_id.value.to_integer_64) as l_node
+				then
+						-- FIXME: there is a mix between CMS interface and API interface here.
+					create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+					l_page.add_variable (l_node, "node")
+					l_page.execute
+				else
+					do_error (req, res, l_id)
+				end
+			else
+					-- Factory
+				new_node (req, res)
+			end
+		end
+
+	do_post (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			u_node: CMS_NODE
+		do
+			to_implement ("Check user permissions!!!")
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if
+						l_id.is_integer and then
+						attached node_api.node (l_id.value.to_integer_64) as l_node
+					then
+						if attached {WSF_STRING} req.form_parameter ("method") as l_method then
+							if l_method.is_case_insensitive_equal ("DELETE") then
+								do_delete (req, res)
+							elseif l_method.is_case_insensitive_equal ("PUT") then
+								do_put (req, res)
+							else
+								(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+							end
+						end
+					else
+						do_error (req, res, l_id)
+					end
+				else
+						-- New node
+						-- FIXME !!!
+					if attached {WSF_STRING} req.form_parameter ("type") as p_type then
+						if attached node_api.content_type (p_type.value) as ct then
+						end
+						create {CMS_PARTIAL_NODE} u_node.make_empty (p_type.url_encoded_value)
+					else
+						create {CMS_PARTIAL_NODE} u_node.make_empty ("")
+					end
+
+					update_node_from_data_form (req, u_node)
+					u_node.set_author (l_user)
+					node_api.new_node (u_node)
+					redirect_to (req.absolute_script_url (""), res)
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+	do_put (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if
+						l_id.is_integer and then
+						attached node_api.node (l_id.value.to_integer_64) as l_node
+					then
+						update_node_from_data_form (req, l_node)
+						l_node.set_author (l_user)
+						node_api.update_node (l_node)
+						redirect_to (req.absolute_script_url (""), res)
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+	do_delete (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			if attached current_user_name (req) then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if
+						l_id.is_integer and then
+						attached node_api.node (l_id.integer_value) as l_node
+					then
+						node_api.delete_node (l_node)
+						res.send (create {CMS_REDIRECTION_RESPONSE_MESSAGE}.make (req.absolute_script_url ("")))
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+feature -- Error
+
+	do_error (req: WSF_REQUEST; res: WSF_RESPONSE; a_id: WSF_STRING)
+			-- Handling error.
+		local
+			l_page: CMS_RESPONSE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (req.absolute_script_url (req.path_info), "request")
+			if a_id.is_integer then
+					-- resource not found
+				l_page.add_variable ("404", "code")
+				l_page.set_status_code (404)
+			else
+					-- bad request
+				l_page.add_variable ("400", "code")
+				l_page.set_status_code (400)
+			end
+			l_page.execute
+		end
+
+feature {NONE} -- Node
+
+	new_node (req: WSF_REQUEST; res: WSF_RESPONSE)
+		local
+			l_page: CMS_RESPONSE
+		do
+			if api.user_has_permission (current_user (req), "create node") then
+				create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+				l_page.execute
+			else
+				send_access_denied (res)
+			end
+		end
+
+feature -- {NONE} Form data
+
+	update_node_from_data_form (req: WSF_REQUEST; a_node: CMS_NODE)
+			-- Extract request form data and build a object
+			-- Node
+		local
+			l_title: detachable READABLE_STRING_32
+			l_summary, l_content, l_format: detachable READABLE_STRING_8
+		do
+			if attached {WSF_STRING} req.form_parameter ("title") as p_title then
+				l_title := p_title.value
+				a_node.set_title (l_title)
+			end
+			if attached {WSF_STRING} req.form_parameter ("summary") as p_summary then
+				l_summary := html_encoded (p_summary.value)
+			end
+			if attached {WSF_STRING} req.form_parameter ("content") as p_content then
+				l_content := html_encoded (p_content.value)
+			end
+			if attached {WSF_STRING} req.form_parameter ("format") as p_format then
+				l_format := p_format.url_encoded_value
+			end
+			if l_format = Void then
+				l_format := a_node.format
+			end
+			a_node.set_content (l_content, l_summary, l_format)
+		end
+
+end

modules/node/handler/experimental/node_resources_handler.e

@@ -0,0 +1,75 @@
+note
+	description: "Request handler related to /nodes."
+	date: "$Date: 2015-02-13 13:08:13 +0100 (ven., 13 févr. 2015) $"
+	revision: "$Revision: 96616 $"
+
+class
+	NODE_RESOURCES_HANDLER
+
+inherit
+	CMS_NODE_HANDLER
+
+	WSF_URI_HANDLER
+		rename
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+			s: STRING
+		do
+				-- At the moment the template is hardcoded, but we can
+				-- get them from the configuration file and load them into
+				-- the setup class.
+
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (node_api.nodes, "nodes")
+
+
+				-- NOTE: for development purposes we have the following hardcode output.
+			create s.make_from_string ("<p>Nodes:</p>")
+			if attached node_api.nodes as lst then
+				across
+					lst as ic
+				loop
+					s.append ("<li>")
+					s.append ("<a href=%"")
+					s.append (req.script_url ("/node/" + ic.item.id.out))
+					s.append ("%">")
+					s.append (api.html_encoded (ic.item.title))
+					s.append (" (")
+					s.append (ic.item.id.out)
+					s.append (")")
+					s.append ("</a>")
+					s.append ("</li>%N")
+				end
+			end
+
+			l_page.set_main_content (s)
+			l_page.add_block (create {CMS_CONTENT_BLOCK}.make ("nodes_warning", Void, "/nodes/ is not yet fully implemented<br/>", Void), "highlighted")
+			l_page.execute
+		end
+
+end

modules/node/handler/experimental/node_summary_handler.e

@@ -0,0 +1,168 @@
+note
+	description: "Summary description for {NODE_SUMMARY_HANDLER}."
+	date: "$Date: 2015-02-13 13:08:13 +0100 (ven., 13 févr. 2015) $"
+	revision: "$Revision: 96616 $"
+
+class
+	NODE_SUMMARY_HANDLER
+
+inherit
+	CMS_NODE_HANDLER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_URI_TEMPLATE_HANDLER
+		rename
+			execute as uri_template_execute,
+			new_mapping as new_uri_template_mapping
+		select
+			new_uri_template_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get,
+			do_post,
+			do_put
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+	uri_template_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+			if attached current_user_name (req) then
+					-- Existing node
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached node_api.node (l_id.integer_value) as l_node then
+						create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+						l_page.add_variable (l_id.value, "id")
+						l_page.add_variable (l_node.summary, "node_summary")
+						l_page.execute
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+
+	do_post (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			if attached current_user_name (req) then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached node_api.node (l_id.integer_value) as l_node then
+						if attached {WSF_STRING} req.form_parameter ("method") as l_method then
+							if l_method.is_case_insensitive_equal ("PUT") then
+								do_put (req, res)
+							else
+								(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+							end
+						end
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+	do_put (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			u_node: CMS_NODE
+		do
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached node_api.node (l_id.integer_value) as l_node then
+						u_node := extract_data_form (req)
+						u_node.set_id (l_id.value.to_integer_64)
+						node_api.update_node_summary (l_user.id,u_node.id, u_node.summary)
+						redirect_to (req.absolute_script_url (""), res)
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+feature -- Error
+
+
+	do_error (req: WSF_REQUEST; res: WSF_RESPONSE; a_id: WSF_STRING)
+			-- Handling error.
+		local
+			l_page: CMS_RESPONSE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (req.absolute_script_url (req.path_info), "request")
+			if a_id.is_integer then
+					-- resource not found
+				l_page.add_variable ("404", "code")
+				l_page.set_status_code (404)
+			else
+					-- bad request
+				l_page.add_variable ("400", "code")
+				l_page.set_status_code (400)
+			end
+			l_page.execute
+		end
+
+
+feature -- {NONE} Form data
+
+
+	extract_data_form (req: WSF_REQUEST): CMS_NODE
+			-- Extract request form data and build a object
+			-- Node
+		do
+			create Result.make ("", "", "")
+			if attached {WSF_STRING}req.form_parameter ("summary") as l_summary then
+				Result.set_summary (l_summary.value)
+			end
+		end
+
+end

modules/node/handler/experimental/node_title_handler.e

@@ -0,0 +1,166 @@
+note
+	description: "Summary description for {NODE_TITLE_HANDLER}."
+	date: "$Date: 2015-02-13 13:08:13 +0100 (ven., 13 févr. 2015) $"
+	revision: "$Revision: 96616 $"
+
+class
+	NODE_TITLE_HANDLER
+
+inherit
+	CMS_NODE_HANDLER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_URI_TEMPLATE_HANDLER
+		rename
+			execute as uri_template_execute,
+			new_mapping as new_uri_template_mapping
+		select
+			new_uri_template_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get,
+			do_post,
+			do_put
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+	uri_template_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+		do
+			if attached current_user_name (req) as l_user then
+					-- Existing node
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached node_api.node (l_id.integer_value) as l_node then
+						create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+						l_page.add_variable (l_node.title, "node_title")
+						l_page.add_variable (l_id.value, "id")
+						l_page.execute
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+	do_post (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			if attached current_user_name (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached node_api.node (l_id.integer_value) as l_node then
+						if attached {WSF_STRING} req.form_parameter ("method") as l_method then
+							if l_method.is_case_insensitive_equal ("PUT") then
+								do_put (req, res)
+							else
+								(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+							end
+						end
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+	do_put (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			u_node: CMS_NODE
+		do
+			to_implement ("Check if user has permissions")
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if l_id.is_integer and then attached node_api.node (l_id.integer_value) as l_node then
+						u_node := extract_data_form (req)
+						u_node.set_id (l_id.value.to_integer_64)
+						node_api.update_node_title (l_user.id, u_node.id, u_node.title)
+						redirect_to (req.absolute_script_url (""), res)
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (res)
+			end
+		end
+
+feature -- Error
+
+	do_error (req: WSF_REQUEST; res: WSF_RESPONSE; a_id: WSF_STRING)
+			-- Handling error.
+		local
+			l_page: CMS_RESPONSE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (req.absolute_script_url (req.path_info), "request")
+			if a_id.is_integer then
+					-- resource not found
+				l_page.add_variable ("404", "code")
+				l_page.set_status_code (404)
+			else
+					-- bad request
+				l_page.add_variable ("400", "code")
+				l_page.set_status_code (400)
+			end
+			l_page.execute
+		end
+
+
+feature -- {NONE} Form data
+
+	extract_data_form (req: WSF_REQUEST): CMS_NODE
+			-- Extract request form data and build a object
+			-- Node
+		do
+			create Result.make ("", "", "")
+			if attached {WSF_STRING} req.form_parameter ("title") as l_title then
+				Result.set_title (l_title.value)
+			end
+		end
+
+end

modules/node/handler/node_form_response.e

@@ -0,0 +1,259 @@
+note
+	description: "CMS Response handling node editing workflow using Web forms."
+	revision: "$Revision$"
+
+class
+	NODE_FORM_RESPONSE
+
+inherit
+	NODE_RESPONSE
+		redefine
+			make,
+			initialize
+		end
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make (req: WSF_REQUEST; res: WSF_RESPONSE; a_api: like api; a_node_api: like node_api)
+		do
+			create {WSF_NULL_THEME} wsf_theme.make
+			Precursor (req, res, a_api, a_node_api)
+		end
+
+	initialize
+		do
+			Precursor
+			create {WSF_CMS_THEME} wsf_theme.make (Current, theme)
+		end
+
+	wsf_theme: WSF_THEME
+
+feature -- Execution
+
+	process
+			-- Computed response message.
+		local
+			b: STRING_8
+			f: like edit_form
+			fd: detachable WSF_FORM_DATA
+			nid: INTEGER_64
+		do
+			create b.make_empty
+			nid := node_id_path_parameter (request)
+			if
+				nid > 0 and then
+				attached node_api.node (nid) as l_node
+			then
+				if attached node_api.node_type_for (l_node) as l_type then
+					if has_permission ("edit " + l_type.name) then
+						f := edit_form (l_node, url (request.path_info, Void), "edit-" + l_type.name, l_type)
+						if request.is_post_request_method then
+							f.validation_actions.extend (agent edit_form_validate (?, b))
+							f.submit_actions.extend (agent edit_form_submit (?, l_node, l_type, b))
+							f.process (Current)
+							fd := f.last_data
+						end
+
+						if attached redirection as l_location then
+								-- FIXME: Hack for now
+							set_title (l_node.title)
+							add_to_menu (create {CMS_LOCAL_LINK}.make ("View", node_url (l_node)), primary_tabs)
+							add_to_menu (create {CMS_LOCAL_LINK}.make ("Edit", "/node/" + l_node.id.out + "/edit"), primary_tabs)
+
+							b.append (html_encoded (l_type.title) + " saved")
+						else
+							set_title ("Edit " + html_encoded (l_type.title) + " #" + l_node.id.out)
+
+							add_to_menu (create {CMS_LOCAL_LINK}.make ("View", node_url (l_node)), primary_tabs)
+							add_to_menu (create {CMS_LOCAL_LINK}.make ("Edit", "/node/" + l_node.id.out + "/edit"), primary_tabs)
+
+							f.append_to_html (wsf_theme, b)
+						end
+					else
+						b.append ("<h1>Access denied</h1>")
+					end
+				else
+					set_title ("Unknown node")
+				end
+			elseif
+				attached {WSF_STRING} request.path_parameter ("type") as p_type and then
+				attached node_api.node_type (p_type.value) as l_type
+			then
+				if has_permission ("create " + l_type.name) then
+					if attached l_type.new_node (Void) as l_node then
+						f := edit_form (l_node, url (request.path_info, Void), "edit-" + l_type.name, l_type)
+						if request.is_post_request_method then
+							f.validation_actions.extend (agent edit_form_validate (?, b))
+							f.submit_actions.extend (agent edit_form_submit (?, l_node, l_type, b))
+							f.process (Current)
+							fd := f.last_data
+						end
+
+						set_title ("Edit " + html_encoded (l_type.title) + " #" + l_node.id.out)
+
+						add_to_menu (create {CMS_LOCAL_LINK}.make ("View", node_url (l_node)), primary_tabs)
+						add_to_menu (create {CMS_LOCAL_LINK}.make ("Edit", "/node/" + l_node.id.out + "/edit"), primary_tabs)
+
+						f.append_to_html (wsf_theme, b)
+					else
+						b.append ("<h1>Server error</h1>")
+					end
+				else
+					b.append ("<h1>Access denied</h1>")
+				end
+			else
+				set_title ("Create new content ...")
+				b.append ("<ul id=%"content-types%">")
+				across
+					node_api.node_types as ic
+				loop
+					if
+						attached ic.item as l_node_type and then
+						(has_permission ("create any") or has_permission ("create " + l_node_type.name))
+					then
+						b.append ("<li>" + link (l_node_type.name, "/node/add/" + l_node_type.name, Void))
+						if attached l_node_type.description as d then
+							b.append ("<div class=%"description%">" + d + "</div>")
+						end
+						b.append ("</li>")
+					end
+				end
+				b.append ("</ul>")
+			end
+			set_main_content (b)
+		end
+
+feature -- Form	
+
+	edit_form_validate (fd: WSF_FORM_DATA; b: STRING)
+		local
+			l_preview: BOOLEAN
+			l_format: detachable CONTENT_FORMAT
+		do
+			l_preview := attached {WSF_STRING} fd.item ("op") as l_op and then l_op.same_string ("Preview")
+			if l_preview then
+				b.append ("<strong>Preview</strong><div class=%"preview%">")
+				if attached fd.string_item ("format") as s_format and then attached api.format (s_format) as f_format then
+					l_format := f_format
+				end
+				if attached fd.string_item ("title") as l_title then
+					b.append ("<strong>Title:</strong><div class=%"title%">" + html_encoded (l_title) + "</div>")
+				end
+				if attached fd.string_item ("body") as l_body then
+					b.append ("<strong>Body:</strong><div class=%"body%">")
+					if l_format /= Void then
+						b.append (l_format.formatted_output (l_body))
+					else
+						b.append (html_encoded (l_body))
+					end
+					b.append ("</div>")
+				end
+				b.append ("</div>")
+			end
+		end
+
+	edit_form_submit (fd: WSF_FORM_DATA; a_node: detachable CMS_NODE; a_type: CMS_NODE_TYPE [CMS_NODE]; b: STRING)
+		local
+			l_preview: BOOLEAN
+			l_node: detachable CMS_NODE
+			s: STRING
+		do
+			l_preview := attached {WSF_STRING} fd.item ("op") as l_op and then l_op.same_string ("Preview")
+			if not l_preview then
+				debug ("cms")
+					across
+						fd as c
+					loop
+						b.append ("<li>" +  html_encoded (c.key) + "=")
+						if attached c.item as v then
+							b.append (html_encoded (v.string_representation))
+						end
+						b.append ("</li>")
+					end
+				end
+				if a_node /= Void then
+					l_node := a_node
+					if l_node.has_id then
+						change_node (a_type, fd, a_node)
+						s := "modified"
+					else
+						change_node (a_type, fd, a_node)
+						l_node.set_author (user)
+						s := "created"
+					end
+				else
+					l_node := new_node (a_type, fd, Void)
+					l_node.set_author (user)
+					s := "created"
+				end
+				node_api.save_node (l_node)
+				if attached current_user (request) as u then
+					api.log ("node", "User %"" + user_link (u) + "%" " + s + " node " + link (a_type.name +" #" + l_node.id.out, "/node/" + l_node.id.out , Void), 0, node_local_link (l_node))
+				else
+					api.log ("node", "Anonymous " + s + " node " + a_type.name +" #" + l_node.id.out, 0, node_local_link (l_node))
+				end
+				add_success_message ("Node #" + l_node.id.out + " saved.")
+				set_redirection (node_url (l_node))
+			end
+		end
+
+	edit_form (a_node: detachable CMS_NODE; a_url: READABLE_STRING_8; a_name: STRING; a_type: CMS_NODE_TYPE [CMS_NODE]): CMS_FORM
+		local
+			f: CMS_FORM
+			ts: WSF_FORM_SUBMIT_INPUT
+			th: WSF_FORM_HIDDEN_INPUT
+		do
+			create f.make (a_url, a_name)
+
+			create th.make ("node-id")
+			if a_node /= Void then
+				th.set_text_value (a_node.id.out)
+			else
+				th.set_text_value ("0")
+			end
+			f.extend (th)
+
+			fill_edit_form (a_type, f, a_node)
+
+			f.extend_html_text ("<br/>")
+
+			create ts.make ("op")
+			ts.set_default_value ("Save")
+			f.extend (ts)
+
+			create ts.make ("op")
+			ts.set_default_value ("Preview")
+			f.extend (ts)
+
+			Result := f
+		end
+
+	new_node (a_content_type: CMS_NODE_TYPE [CMS_NODE]; a_form_data: WSF_FORM_DATA; a_node: detachable CMS_NODE): CMS_NODE
+			--
+		do
+			if attached node_api.node_type_webform_manager (a_content_type) as wf then
+				Result := wf.new_node (Current, a_form_data, a_node)
+			else
+				Result := a_content_type.new_node (a_node)
+			end
+		end
+
+	change_node (a_content_type: CMS_NODE_TYPE [CMS_NODE]; a_form_data: WSF_FORM_DATA; a_node: CMS_NODE)
+			-- Update node `a_node' with form_data `a_form_data' for the given content type `a_content_type'.
+		do
+			if attached node_api.node_type_webform_manager (a_content_type) as wf then
+				wf.update_node (Current, a_form_data, a_node)
+			end
+		end
+
+	fill_edit_form (a_content_type: CMS_NODE_TYPE [CMS_NODE]; a_form: WSF_FORM; a_node: detachable CMS_NODE)
+		do
+			if attached node_api.node_type_webform_manager (a_content_type) as wf then
+				wf.populate_form (Current, a_form, a_node)
+			end
+		end
+
+end

modules/node/handler/node_handler.e

@@ -0,0 +1,205 @@
+note
+	description: "[
+			handler for CMS node in the CMS interface.
+			
+			TODO: implement REST API.
+			]"
+	date: "$Date: 2015-02-13 13:08:13 +0100 (ven., 13 févr. 2015) $"
+	revision: "$Revision: 96616 $"
+
+class
+	NODE_HANDLER
+
+inherit
+	CMS_NODE_HANDLER
+
+	WSF_URI_HANDLER
+		rename
+			execute as uri_execute,
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_URI_TEMPLATE_HANDLER
+		rename
+			execute as uri_template_execute,
+			new_mapping as new_uri_template_mapping
+		select
+			new_uri_template_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get,
+			do_post,
+			do_put,
+			do_delete
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+	uri_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+	uri_template_execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute (req, res)
+		end
+
+feature -- Query
+
+	node_id_path_parameter (req: WSF_REQUEST): INTEGER_64
+			-- Node id passed as path parameter for request `req'.
+		local
+			s: STRING
+		do
+			if attached {WSF_STRING} req.path_parameter ("id") as p_nid then
+				s := p_nid.value
+				if s.is_integer_64 then
+					Result := s.to_integer_64
+				end
+			end
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_node: detachable CMS_NODE
+			l_nid: INTEGER_64
+			edit_response: NODE_FORM_RESPONSE
+			view_response: NODE_VIEW_RESPONSE
+		do
+			if req.path_info.ends_with_general ("/edit") then
+				check valid_url: req.path_info.starts_with_general ("/node/") end
+				create edit_response.make (req, res, api, node_api)
+				edit_response.execute
+			else
+					-- Display existing node
+				l_nid := node_id_path_parameter (req)
+				if l_nid > 0 then
+					l_node := node_api.node (l_nid)
+					if l_node /= Void then
+						create view_response.make (req, res, api, node_api)
+						view_response.set_node (l_node)
+						view_response.execute
+					else
+						send_not_found (req, res)
+					end
+				else
+--					redirect_to (req.absolute_script_url ("/node/"), res) -- New node.
+--					send_bad_request (req, res)
+					create_new_node (req, res)
+				end
+			end
+		end
+
+	do_post (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			edit_response: NODE_FORM_RESPONSE
+		do
+			if req.path_info.ends_with_general ("/edit") then
+				create edit_response.make (req, res, api, node_api)
+				edit_response.execute
+--			elseif req.path_info.same_string_general ("/node/") then
+--				create edit_response.make (req, res, api, node_api)
+--				edit_response.execute
+			else
+				to_implement ("REST API")
+				send_not_implemented ("REST API not yet implemented", req, res)
+			end
+		end
+
+	do_put (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			to_implement ("REST API")
+			send_not_implemented ("REST API not yet implemented", req, res)
+		end
+
+	do_delete (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		do
+			if attached current_user (req) as l_user then
+				if attached {WSF_STRING} req.path_parameter ("id") as l_id then
+					if
+						l_id.is_integer and then
+						attached node_api.node (l_id.integer_value) as l_node
+					then
+						if api.user_has_permission (l_user, "delete " + l_node.content_type) then
+							node_api.delete_node (l_node)
+							res.send (create {CMS_REDIRECTION_RESPONSE_MESSAGE}.make (req.absolute_script_url ("")))
+						else
+							send_access_denied (req, res)
+						end
+					else
+						do_error (req, res, l_id)
+					end
+				else
+					(create {INTERNAL_SERVER_ERROR_CMS_RESPONSE}.make (req, res, api)).execute
+				end
+			else
+				send_access_denied (req, res)
+			end
+		end
+
+	process_node_creation (req: WSF_REQUEST; res: WSF_RESPONSE; a_user: CMS_USER)
+		do
+			to_implement ("REST API")
+			send_not_implemented ("REST API not yet implemented", req, res)
+		end
+
+feature -- Error
+
+	do_error (req: WSF_REQUEST; res: WSF_RESPONSE; a_id: detachable WSF_STRING)
+			-- Handling error.
+		local
+			l_page: CMS_RESPONSE
+		do
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (req.absolute_script_url (req.path_info), "request")
+			if a_id /= Void and then a_id.is_integer then
+					-- resource not found
+				l_page.add_variable ("404", "code")
+				l_page.set_status_code (404)
+			else
+					-- bad request
+				l_page.add_variable ("400", "code")
+				l_page.set_status_code (400)
+			end
+			l_page.execute
+		end
+
+feature {NONE} -- Node
+
+	create_new_node (req: WSF_REQUEST; res: WSF_RESPONSE)
+		local
+			edit_response: NODE_FORM_RESPONSE
+		do
+			if req.path_info.starts_with_general ("/node/") then
+				create edit_response.make (req, res, api, node_api)
+				edit_response.execute
+			elseif req.is_get_request_method then
+				redirect_to (req.absolute_script_url ("/node/"), res)
+			else
+				send_bad_request (req, res)
+			end
+		end
+
+end

modules/node/handler/node_response.e

@@ -0,0 +1,86 @@
+note
+	description: "Generic CMS Response for a CMS NODE."
+	date: "$Date$"
+	revision: "$Revision$"
+
+deferred class
+	NODE_RESPONSE
+
+inherit
+	CMS_RESPONSE
+		rename
+			make as make_response
+		redefine
+			custom_prepare
+		end
+
+feature {NONE} -- Initialization
+
+	make (req: WSF_REQUEST; res: WSF_RESPONSE; a_api: like api; a_node_api: like node_api)
+		do
+			node_api := a_node_api
+			make_response (req, res, a_api)
+		end
+
+feature -- Access
+
+	node_api: CMS_NODE_API
+			-- Associated node API.
+
+feature -- Generation
+
+	custom_prepare (page: CMS_HTML_PAGE)
+		do
+			if attached variables as l_variables then
+				across l_variables as c loop page.register_variable (c.item, c.key) end
+			end
+		end
+
+feature -- Helpers
+
+	node_id_path_parameter (req: WSF_REQUEST): INTEGER_64
+			-- Node id passed as path parameter for request `req'.
+		local
+			s: STRING
+		do
+			if attached {WSF_STRING} req.path_parameter ("id") as p_nid then
+				s := p_nid.value
+				if s.is_integer_64 then
+					Result := s.to_integer_64
+				end
+			end
+		end
+
+feature -- Helpers
+
+	user_local_link (u: CMS_USER): CMS_LINK
+		do
+			create {CMS_LOCAL_LINK} Result.make (u.name, user_url (u))
+		end
+
+	node_local_link (n: CMS_NODE): CMS_LINK
+		do
+			create {CMS_LOCAL_LINK} Result.make (n.title, node_url (n))
+		end
+
+	user_link (u: CMS_USER): like link
+		do
+			Result := link (u.name, "/user/" + u.id.out, Void)
+		end
+
+	node_link (n: CMS_NODE): like link
+		do
+			Result := link (n.title, "/node/" + n.id.out, Void)
+		end
+
+	user_url (u: CMS_USER): like url
+		do
+			Result := url ("/user/" + u.id.out, Void)
+		end
+
+	node_url (n: CMS_NODE): like url
+		do
+			Result := url ("/node/" + n.id.out, Void)
+		end
+
+end

modules/node/handler/node_view_response.e

@@ -0,0 +1,75 @@
+note
+	description: "Summary description for {NODE_VIEW_RESPONSE}."
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	NODE_VIEW_RESPONSE
+
+inherit
+	NODE_RESPONSE
+		redefine
+			make,
+			initialize
+		end
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make (req: WSF_REQUEST; res: WSF_RESPONSE; a_api: like api; a_node_api: like node_api)
+		do
+			create {WSF_NULL_THEME} wsf_theme.make
+			Precursor (req, res, a_api, a_node_api)
+		end
+
+	initialize
+		do
+			Precursor
+			create {WSF_CMS_THEME} wsf_theme.make (Current, theme)
+		end
+
+	wsf_theme: WSF_THEME
+
+feature -- Access
+
+	node: detachable CMS_NODE
+
+feature -- Element change
+
+	set_node (a_node: like node)
+		do
+			node := a_node
+		end
+
+feature -- Execution
+
+	process
+			-- Computed response message.
+		local
+			b: STRING_8
+			nid: INTEGER_64
+			l_node: like node
+		do
+			l_node := node
+			if l_node = Void then
+				create b.make_empty
+				nid := node_id_path_parameter (request)
+				if nid > 0 then
+					l_node := node_api.node (nid)
+				end
+			end
+			if l_node /= Void then
+				if
+					attached node_api.node_type_for (l_node) as l_content_type and then
+					attached node_api.node_type_webform_manager (l_content_type) as l_manager
+				then
+					l_manager.append_html_output_to (l_node, Current)
+				end
+			else
+				set_main_content ("Missing node")
+			end
+		end
+
+end

modules/node/handler/nodes_handler.e

@@ -0,0 +1,72 @@
+note
+	description: "Request handler related to /nodes."
+	date: "$Date: 2015-02-13 13:08:13 +0100 (ven., 13 févr. 2015) $"
+	revision: "$Revision: 96616 $"
+
+class
+	NODES_HANDLER
+
+inherit
+	CMS_NODE_HANDLER
+
+	WSF_URI_HANDLER
+		rename
+			new_mapping as new_uri_mapping
+		end
+
+	WSF_RESOURCE_HANDLER_HELPER
+		redefine
+			do_get
+		end
+
+	REFACTORING_HELPER
+
+create
+	make
+
+feature -- execute
+
+	execute (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Execute request handler
+		do
+			execute_methods (req, res)
+		end
+
+feature -- HTTP Methods
+
+	do_get (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- <Precursor>
+		local
+			l_page: CMS_RESPONSE
+			s: STRING
+			n: CMS_NODE
+		do
+				-- At the moment the template is hardcoded, but we can
+				-- get them from the configuration file and load them into
+				-- the setup class.
+
+			create {GENERIC_VIEW_CMS_RESPONSE} l_page.make (req, res, api)
+			l_page.add_variable (node_api.nodes, "nodes")
+
+
+				-- NOTE: for development purposes we have the following hardcode output.
+			create s.make_from_string ("<p>Nodes:</p>")
+			if attached node_api.nodes as lst then
+				s.append ("<ul class=%"cms-nodes%">%N")
+				across
+					lst as ic
+				loop
+					n := ic.item
+					s.append ("<li class=%"cms_type_"+ n.content_type +"%">")
+					s.append (l_page.link (n.title + " (#" + n.id.out + ")", node_api.node_path (n), Void))
+					s.append ("</li>%N")
+				end
+				s.append ("</ul>%N")
+			end
+
+			l_page.set_main_content (s)
+			l_page.add_block (create {CMS_CONTENT_BLOCK}.make ("nodes_warning", Void, "/nodes/ is not yet fully implemented<br/>", Void), "highlighted")
+			l_page.execute
+		end
+
+end

modules/node/handler/wsf_cms_theme.e

@@ -0,0 +1,58 @@
+note
+	description: "Summary description for {WSF_CMS_THEME}."
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	WSF_CMS_THEME
+
+inherit
+	WSF_THEME
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make (res: CMS_RESPONSE; a_cms_theme: CMS_THEME)
+		do
+			request := res.request
+			cms_theme := a_cms_theme
+			set_response (res)
+		end
+
+feature -- Access
+
+	request: WSF_REQUEST
+
+	response: detachable CMS_RESPONSE
+
+	cms_theme: CMS_THEME
+
+feature -- Element change
+
+	set_response (a_response: CMS_RESPONSE)
+		do
+			response := a_response
+		end
+
+feature -- Core
+
+	site_url: READABLE_STRING_8
+		do
+			if attached response as r then
+				Result := r.site_url
+			else
+				Result := request.absolute_script_url ("")
+			end
+		end
+
+	base_url: detachable READABLE_STRING_8
+			-- Base url if any.
+		do
+			if attached response as r then
+				Result := r.base_url
+			end
+		end
+
+end

modules/node/handler/wsf_null_theme.e

@@ -0,0 +1,30 @@
+note
+	description: " Null theme for void-safety purpose."
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	WSF_NULL_THEME
+
+inherit
+	WSF_THEME
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make
+		do
+		end
+
+feature -- Core
+
+	site_url: STRING = ""
+
+	base_url: detachable READABLE_STRING_8
+			-- Base url if any.
+		do
+		end
+
+end