Simplified EWSGI interfaces

Renamed WGI_RESPONSE_BUFFER as WGI_RESPONSE to avoid confusion Removed EWF_HEADER and removed related caller from WGI implementation, now this is only part of WSF library Added wgi_version, wgi_implementation and wgi_connector to the WGI_REQUEST interface to give more information to the user Added back WGI_CONNECTOR to WGI specification, mainly because of `{WGI_REQUEST}.wgi_connector' simplified WGI_CONNECTOR to contain for now only `name' and `version' if the implementation of connector inherit from WGI_CONNECTOR (recommended) this might gives more access to the user using a reverse assignment for specific needs (but this usage is not recommended due to portability issue on other connector) Removed useless connector.ecf since now EWF/WGI library provides the helper classes
2011-11-25 14:39:48 +01:00
parent 3032b91ff7
commit fd0912904c
24 changed files with 553 additions and 627 deletions
--- a/library/server/ewsgi/specification/response/wgi_response.e
+++ b/library/server/ewsgi/specification/response/wgi_response.e
@@ -0,0 +1,120 @@
+note
+	description: "Summary description for {WGI_RESPONSE}."
+	date: "$Date$"
+	revision: "$Revision$"
+
+deferred class
+	WGI_RESPONSE
+
+feature {WGI_SERVICE} -- Commit
+
+	commit
+			-- Commit the current response
+		deferred
+		ensure
+			status_is_set: status_is_set
+			header_committed: header_committed
+			message_committed: message_committed
+		end
+
+feature -- Status report
+
+	header_committed: BOOLEAN
+			-- Header committed?
+		deferred
+		end
+
+	message_committed: BOOLEAN
+			-- Message committed?
+		deferred
+		end
+
+	message_writable: BOOLEAN
+			-- Can message be written?
+		deferred
+		end
+
+feature {WGI_RESPONSE_BUFFER} -- Core output operation
+
+	write (s: READABLE_STRING_8)
+			-- Send the string `s'
+			-- this can be used for header and body
+		deferred
+		end
+
+feature -- Status setting
+
+	status_is_set: BOOLEAN
+			-- Is status set?
+		deferred
+		end
+
+	set_status_code (a_code: INTEGER)
+			-- Set response status code
+			-- Should be done before sending any data back to the client
+		require
+			status_not_set: not status_is_set
+			header_not_committed: not header_committed
+		deferred
+		ensure
+			status_code_set: status_code = a_code
+			status_set: status_is_set
+		end
+
+	status_code: INTEGER
+			-- Response status
+		deferred
+		end
+
+feature -- Header output operation
+
+	write_headers (a_headers: READABLE_STRING_8)
+		require
+			status_set: status_is_set
+			header_not_committed: not header_committed
+		deferred
+		ensure
+			status_set: status_is_set
+			header_committed: header_committed
+			message_writable: message_writable
+		end
+
+feature -- Output operation
+
+	write_string (s: READABLE_STRING_8)
+			-- Send the string `s'
+		require
+			message_writable: message_writable
+		deferred
+		end
+
+	write_substring (s: READABLE_STRING_8; a_begin_index, a_end_index: INTEGER)
+			-- Send the substring `s[a_begin_index:a_end_index]'
+		require
+			message_writable: message_writable
+		deferred
+		end
+
+	write_file_content (fn: READABLE_STRING_8)
+			-- Send the content of file `fn'
+		require
+			message_writable: message_writable
+		deferred
+		end
+
+	flush
+			-- Flush if it makes sense
+		deferred
+		end
+
+note
+	copyright: "2011-2011, Eiffel Software and others"
+	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
+	source: "[
+			Eiffel Software
+			5949 Hollister Ave., Goleta, CA 93117 USA
+			Telephone 805-685-1006, Fax 805-685-6869
+			Website http://www.eiffel.com
+			Customer support http://support.eiffel.com
+		]"
+end