Introduce WSF_COMPRESSION and applied to WSF_*_WITH_COMPRESSION classes.

Modified the example to send the file with or without compression.

.travis.yml

@@ -0,0 +1,19 @@
+language: eiffel
+before_script:
+    - export current_dir=$PWD ; echo current_dir=$current_dir ; cd ..
+    - export ISE_VERSION=17.05; export ISE_BUILD=100416
+    - curl -sSL http://downloads.sourceforge.net/eiffelstudio/Eiffel_${ISE_VERSION}_gpl_${ISE_BUILD}-linux-x86-64.tar.bz2 | tar -x --bzip2
+    - export ISE_EIFFEL=$PWD/Eiffel_${ISE_VERSION} ; export ISE_PLATFORM=linux-x86-64
+    - export PATH=$PATH:$ISE_EIFFEL/studio/spec/$ISE_PLATFORM/bin:$PATH:$ISE_EIFFEL/tools/spec/$ISE_PLATFORM/bin
+    - echo `ec -version`
+    - cd $current_dir
+    - echo Check projects compilation status...
+    
+branches:
+  only:
+  - master
+  - v1
+  
+script: compile_all -ecb -melt -list_failures -log_verbose -clean -options dotnet=false
+group: stable
+os: linux

examples/simple_compression/service.ini

@@ -0,0 +1,4 @@
+port=9090
+verbose=true
+socket_recv_timeout=15
+keep_alive_timeout=30

examples/simple_compression/service_compression.e

@@ -0,0 +1,26 @@
+note
+	description : "simple application root class"
+	date        : "$Date$"
+	revision    : "$Revision$"
+
+class
+	SERVICE_COMPRESSION
+
+inherit
+	WSF_DEFAULT_SERVICE [SERVICE_COMPRESSION_EXECUTION]
+		redefine
+			initialize
+		end
+
+create
+	make_and_launch
+
+feature {NONE} -- Initialization
+
+	initialize
+		do
+			Precursor
+			import_service_options (create {WSF_SERVICE_LAUNCHER_OPTIONS_FROM_INI}.make_from_file ("service.ini"))
+		end
+
+end

examples/simple_compression/service_compression.ecf

@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="ISO-8859-1"?>
+<system xmlns="http://www.eiffel.com/developers/xml/configuration-1-15-0" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.eiffel.com/developers/xml/configuration-1-15-0 http://www.eiffel.com/developers/xml/configuration-1-15-0.xsd" name="service_compression" uuid="C28C4F53-9963-46C0-A080-8F13E94E7486">
+	<target name="service_compression">
+		<root class="SERVICE_COMPRESSION" feature="make_and_launch"/>
+		<option warning="true" void_safety="all">
+			<assertions precondition="true" postcondition="true" check="true" invariant="true" loop="true" supplier_precondition="true"/>
+		</option>
+		<setting name="concurrency" value="scoop"/>
+		<library name="base" location="$ISE_LIBRARY\library\base\base-safe.ecf"/>
+		<library name="default_standalone" location="..\..\library\server\wsf\default\standalone-safe.ecf"/>
+		<library name="http" location="..\..\library\network\protocol\http\http-safe.ecf"/>
+		<library name="wsf" location="..\..\library\server\wsf\wsf-safe.ecf" readonly="false"/>
+		<library name="wsf_compression" location="..\..\library\server\wsf\wsf_compression-safe.ecf" readonly="false"/>
+		<cluster name="service_compression" location=".\" recursive="true">
+			<file_rule>
+				<exclude>/EIFGENs$</exclude>
+				<exclude>/CVS$</exclude>
+				<exclude>/.svn$</exclude>
+			</file_rule>
+		</cluster>
+	</target>
+</system>

examples/simple_compression/service_compression_execution.e

@@ -0,0 +1,68 @@
+note
+	description: "Simple file execution, serving home.html, ewf.png and 404.html"
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	SERVICE_COMPRESSION_EXECUTION
+
+inherit
+	WSF_ROUTED_EXECUTION
+		redefine
+			initialize,
+			execute_default
+		end
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+
+	initialize
+			-- Initialize current service.
+		do
+			Precursor
+			initialize_router
+		end
+
+	setup_router
+		local
+			fhdl_with_compression: WSF_FILE_SYSTEM_HANDLER_WITH_COMPRESSION
+			fhdl: WSF_FILE_SYSTEM_HANDLER
+ 		do
+ 			create fhdl_with_compression.make_hidden ("www")
+ 			fhdl_with_compression.set_directory_index (<<"index.html">>)
+ 			fhdl_with_compression.compression.set_default_compression_format
+ 			fhdl_with_compression.compression.enable_compression_for_media_type ({HTTP_MIME_TYPES}.image_jpg)
+ 			fhdl_with_compression.set_not_found_handler (agent  (ia_uri: READABLE_STRING_8; ia_req: WSF_REQUEST; ia_res: WSF_RESPONSE)
+				do
+					execute_default (ia_req, ia_res)
+				end)
+ 			router.handle ("/compressed/", fhdl_with_compression, router.methods_GET)
+
+ 			create fhdl.make_hidden ("www")
+ 			fhdl.set_directory_index (<<"index.html">>)
+ 			fhdl.set_not_found_handler (agent  (ia_uri: READABLE_STRING_8; ia_req: WSF_REQUEST; ia_res: WSF_RESPONSE)
+				do
+					execute_default (ia_req, ia_res)
+				end)
+ 			router.handle ("/", fhdl, router.methods_GET)
+		end
+
+
+	execute_default (req: WSF_REQUEST; res: WSF_RESPONSE)
+			-- Dispatch requests without a matching handler.
+		local
+			not_found: WSF_NOT_FOUND_RESPONSE
+			mesg: WSF_RESPONSE_MESSAGE
+		do
+			create not_found.make (request)
+			not_found.add_suggested_location (request.absolute_script_url (""), "Home", "Back to home page")
+			mesg := not_found
+			res.send (mesg)
+		end
+
+
+
+end

examples/simple_compression/www/index.html

@@ -0,0 +1,27 @@
+<html>
+	<head>
+		<title>EWF simple_file example</title>
+	</head>
+
+	<body>
+		<h1>EWF simple_file example</h1>
+		<p>This is a static html file served by EWF.</p>
+		<p>Try to <a href="nowhere.html">get lost</a>.</p>
+		<div width="45%" style="display: inline-block; border: solid 1px black; padding: 10px; margin: 10px;">
+		<h2>Without any compression</h2>
+		<a href="ewf.png"><img src="ewf.png"/></a>
+		<p>This is the real Eiffel tower.</p>
+		<a href="eiffel.jpg"><img src="eiffel.jpg"/></a>
+		<p>Try to <a href="big_file2.html">load a big file</a>.</p>
+		</div>
+
+		<div width="45%" style="display: inline-block; border: solid 1px black; padding: 10px; margin: 10px;">
+		<h2>With gzip compression</h2>
+		<a href="compressed/ewf.png"><img src="compressed/ewf.png"/></a>
+		<p>This is the real Eiffel tower.</p>
+		<a href="compressed/eiffel.jpg"><img src="compressed/eiffel.jpg"/></a>
+		<p>Try to <a href="compressed/big_file2.html">load a compressed big file</a>.</p>
+		</div>
+	</body>
+
+</html>

library/security/jwt/src/jwt_encoder.e

@@ -266,11 +266,10 @@ feature {NONE} -- Implementation
 
 	base64_hmacsha256 (s: READABLE_STRING_8; a_secret: READABLE_STRING_8): STRING_8
 		local
-			hs256: HMAC_SHA256
+			ut: JWT_UTILITIES
 		do
-			create hs256.make_ascii_key (a_secret)
-			hs256.update_from_string (s)
-			Result := hs256.base64_digest --lowercase_hexadecimal_string_digest
+			create ut
+			Result := ut.base64_hmacsha256 (s, a_secret)
 		end
 
 end

library/security/jwt/src/jwt_utilities.e

@@ -61,7 +61,33 @@ feature -- Encoding
 		do
 			create hs256.make_ascii_key (a_secret)
 			hs256.update_from_string (s)
-			Result := hs256.base64_digest --lowercase_hexadecimal_string_digest
+			-- if Version >= EiffelStudio 17.11 then
+			-- 	Result := hs256.base64_digest --lowercase_hexadecimal_string_digest
+			-- else
+			Result := base64_bytes_encoded_string (hs256.digest)
+			-- end
+		end
+
+feature {NONE} -- Implementation
+
+	base64_bytes_encoded_string (a_bytes: SPECIAL [NATURAL_8]): STRING_8
+			-- Base64 string from `a_bytes`.
+			--| Note: to be removed when 17.11 is not latest release anymore.
+		local
+			s: STRING
+			i,n: INTEGER
+		do
+			from
+				i := 1
+				n := a_bytes.count
+				create s.make (n)
+			until
+				i > n
+			loop
+				s.append_code (a_bytes[i - 1])
+				i := i + 1
+			end
+			Result := (create {BASE64}).encoded_string (s)
 		end
 
 feature -- Decoding

library/server/wsf/compression/wsf_compression.e

@@ -0,0 +1,205 @@
+note
+	description: "Summary description for {WSF_COMPRESSION}."
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	WSF_COMPRESSION
+
+create
+	make
+
+feature {NONE} -- Initialization	
+
+	make
+			-- Initialize compression support, by default no compression
+ 			-- Gzip with the following media types
+			-- applications/javascript
+			-- application/json
+			-- application/xml
+			-- text/css
+			-- text/html
+			--
+		do
+				-- compression algorithms
+			create {ARRAYED_LIST [STRING]} compression_supported_formats.make (0)
+			compression_supported_formats.compare_objects
+
+				-- media types supported by compression.
+			create {ARRAYED_LIST [STRING]} compression_enabled_media_types.make (0)
+			compression_enabled_media_types.compare_objects
+			set_default_compression_enabled_media_types
+		end
+
+feature -- Query
+
+	encoding_variants (req: WSF_REQUEST; ct: STRING): detachable HTTP_ACCEPT_ENCODING_VARIANTS
+			-- If the client support compression and the server support one of the algorithms
+			-- compress it and update the response header.
+		local
+			conneg : SERVER_CONTENT_NEGOTIATION
+		do
+			if
+				attached req.http_accept_encoding as l_http_encoding and then
+				not compression_supported_formats.is_empty and then
+				compression_enabled_media_types.has (ct)
+			then
+				create conneg.make ("", "", "", "")
+				Result := conneg.encoding_preference (compression_supported_formats, l_http_encoding)
+				if not Result.is_acceptable then
+					Result := Void
+				end
+			end
+		end
+
+feature -- Compression: constants
+
+	gzip_compression_format: STRING = "gzip"
+			-- RFC 1952 (gzip compressed format).	
+
+	deflate_compression_format: STRING = "deflate"
+			-- RFC 1951 (deflate compressed format).
+
+	compress_compression_format: STRING = "compress"
+			-- RFC 1950 (zlib compressed format).
+
+feature -- Compression
+
+	compression_supported_formats : LIST [STRING]
+			-- Server side compression supported formats.
+			-- Supported compression agorithms: `gzip_compression_format', `deflate_compression_format', `compress_compression_format'.
+			-- identity,  means no compression at all.
+
+	compression_enabled_media_types: LIST [STRING]
+			-- List of media types supported by compression.
+
+	set_default_compression_format
+			-- gzip default format.
+		do
+			enable_gzip_compression
+		end
+
+	disable_all_compression_formats
+			-- Remove all items.
+		do
+			compression_supported_formats.wipe_out
+		end
+
+	enable_gzip_compression
+			-- add 'gzip' format to the list of 'compression_supported' formats.
+		do
+			compression_supported_formats.force (gzip_compression_format)
+		ensure
+			has_gzip: compression_supported_formats.has (gzip_compression_format)
+		end
+
+	disable_gzip_compression
+			-- remove 'gzip' format to the list of 'compression_supported' formats.
+		do
+			compression_supported_formats.prune (gzip_compression_format)
+		ensure
+			not_gzip: not compression_supported_formats.has (gzip_compression_format)
+		end
+
+	enable_deflate_compression
+			-- add 'deflate' format to the list of 'compression_supported' formats.
+		do
+			compression_supported_formats.force (deflate_compression_format)
+		ensure
+			has_deflate: compression_supported_formats.has (deflate_compression_format)
+		end
+
+	disable_deflate_compression
+			-- remove 'deflate' format to the list of 'compression_supported' formats.
+		do
+			compression_supported_formats.prune (deflate_compression_format)
+		ensure
+			not_deflate: not compression_supported_formats.has (deflate_compression_format)
+		end
+
+	enable_compress_compression
+			-- add 'compress' format to the list of 'compression_supported' formats
+		do
+			compression_supported_formats.force (compress_compression_format)
+		ensure
+			has_compress: compression_supported_formats.has (compress_compression_format)
+		end
+
+	disable_compress_compression
+			-- remove 'deflate' format to the list of 'compression_supported' formats.
+		do
+			compression_supported_formats.prune (compress_compression_format)
+		ensure
+			no_compress: not compression_supported_formats.has (compress_compression_format)
+		end
+
+feature -- Compression: media types
+
+	set_default_compression_enabled_media_types
+			-- Default media types
+			-- applications/javascript
+			-- application/json
+			-- application/xml
+			-- text/css
+			-- text/html
+			-- text/plain			
+		do
+			compression_enabled_media_types.force ({HTTP_MIME_TYPES}.application_javascript)
+			compression_enabled_media_types.force ({HTTP_MIME_TYPES}.application_json)
+			compression_enabled_media_types.force ({HTTP_MIME_TYPES}.application_xml)
+			compression_enabled_media_types.force ({HTTP_MIME_TYPES}.text_css)
+			compression_enabled_media_types.force ({HTTP_MIME_TYPES}.text_html)
+			compression_enabled_media_types.force ({HTTP_MIME_TYPES}.text_plain)
+		end
+
+	remove_all_compression_enabled_media_types
+			-- Remove all items.
+		do
+			compression_enabled_media_types.wipe_out
+		end
+
+	enable_compression_for_media_type (a_media_type: STRING)
+		do
+			compression_enabled_media_types.force (a_media_type)
+		ensure
+			has_media_type: compression_enabled_media_types.has (a_media_type)
+		end
+
+feature -- Compress Data
+
+ 	compressed_string (a_string: STRING; a_encoding: STRING): STRING
+ 			-- Compress `a_string' using `deflate_compression_format'
+		local
+			dc: ZLIB_STRING_COMPRESS
+		do
+			create Result.make_empty
+			create dc.string_stream_with_size (Result, 32_768) -- chunk size 32k
+			dc.put_string_with_options (a_string, {ZLIB_CONSTANTS}.Z_default_compression, zlb_strategy (a_encoding), {ZLIB_CONSTANTS}.Z_mem_level_9, {ZLIB_CONSTANTS}.z_default_strategy.to_integer_32)
+				-- We use the default compression level
+				-- We use the default value for windows bits, the range is 8..15. Higher values use more memory, but produce smaller output.
+				-- Memory: Higher values use more memory, but are faster and produce smaller output. The default is 8, we use 9.
+		end
+
+	zlb_strategy (a_encoding: STRING): INTEGER
+		do
+			if a_encoding.is_case_insensitive_equal_general (gzip_compression_format) then
+				Result := {ZLIB_CONSTANTS}.z_default_window_bits + 16
+			elseif a_encoding.is_case_insensitive_equal_general (deflate_compression_format) then
+				Result := -{ZLIB_CONSTANTS}.z_default_window_bits
+			else
+				check compress: a_encoding.is_case_insensitive_equal_general (compress_compression_format)  end
+				Result := {ZLIB_CONSTANTS}.z_default_window_bits
+			end
+		end
+
+note
+	copyright: "2011-2017, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Colin Adams, Eiffel Software and others"
+	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
+	source: "[
+			Eiffel Software
+			5949 Hollister Ave., Goleta, CA 93117 USA
+			Telephone 805-685-1006, Fax 805-685-6869
+			Website http://www.eiffel.com
+			Customer support http://support.eiffel.com
+		]"
+end

library/server/wsf/compression/wsf_file_response_with_compression.e

@@ -0,0 +1,113 @@
+note
+	description: "Summary description for {WSF_FILE_RESPONSE_WITH_COMPRESSION}."
+	author: ""
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	WSF_FILE_RESPONSE_WITH_COMPRESSION
+
+inherit
+	WSF_FILE_RESPONSE
+		redefine
+			send_to
+		end
+
+create
+	make_with_path,
+	make_with_content_type_and_path,
+	make_html_with_path,
+	make,
+	make_with_content_type,
+	make_html
+
+feature {NONE} -- Access
+
+	compression_variants: detachable HTTP_ACCEPT_ENCODING_VARIANTS
+
+	compression: detachable WSF_COMPRESSION
+
+feature -- Compression setting
+
+	apply_compression (a_compression: WSF_COMPRESSION; req: WSF_REQUEST)
+		do
+			compression := a_compression
+			compression_variants :=  a_compression.encoding_variants (req, content_type)
+		end
+
+	reset_compression
+		do
+			compression := Void
+			compression_variants := Void
+		end
+
+feature {WSF_RESPONSE} -- Output
+
+	send_to (res: WSF_RESPONSE)
+		do
+			if status_code = {HTTP_STATUS_CODE}.not_found then
+					-- File not found, then no more data.
+			elseif
+				attached compression as l_compression and then
+				attached compression_variants as l_compression_variants and then
+				attached l_compression_variants.encoding as l_encoding and then
+				attached l_compression_variants.vary_header_value as l_vary_header
+			then
+				send_compressed_to (res, l_compression, l_encoding, l_vary_header)
+			else
+					-- Send uncompressed...
+				Precursor (res)
+			end
+		end
+
+	send_compressed_to (res: WSF_RESPONSE; a_compression: WSF_COMPRESSION; a_comp_encoding, a_comp_vary_header: READABLE_STRING_8)
+		local
+			s: detachable READABLE_STRING_8
+			l_content, l_compressed_content: STRING_8
+			f: RAW_FILE
+			l_count: INTEGER
+		do
+			res.set_status_code (status_code)
+			create f.make_with_path (file_path)
+			l_count := f.count
+			f.open_read
+			f.read_stream (l_count)
+			f.close
+			l_content := f.last_string
+
+			s := head
+			if s /= Void then
+				l_content.prepend (s)
+			end
+			s := bottom
+			if s /= Void then
+				l_content.append_string (s)
+			end
+
+			l_compressed_content := a_compression.compressed_string (l_content, a_comp_encoding)
+
+			debug
+				res.put_error (l_content.count.out + " -(compression-> " + l_compressed_content.count.out + "%N")
+			end
+			header.put_content_encoding (a_comp_encoding)
+			header.add_header ("Vary:" + a_comp_vary_header)
+			header.put_content_length (l_compressed_content.count)
+
+			res.put_header_text (header.string)
+			if not answer_head_request_method then
+				res.put_string (l_compressed_content)
+			end
+		end
+
+
+note
+	copyright: "2011-2017, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Colin Adams, Eiffel Software and others"
+	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
+	source: "[
+			Eiffel Software
+			5949 Hollister Ave., Goleta, CA 93117 USA
+			Telephone 805-685-1006, Fax 805-685-6869
+			Website http://www.eiffel.com
+			Customer support http://support.eiffel.com
+		]"
+end

library/server/wsf/compression/wsf_file_system_handler_with_compression.e

@@ -0,0 +1,84 @@
+note
+	description: "Summary description for {WSF_FILE_SYSTEM_HANDLER_WITH_COMPRESSION}."
+	author: ""
+	date: "$Date$"
+	revision: "$Revision$"
+
+class
+	WSF_FILE_SYSTEM_HANDLER_WITH_COMPRESSION
+
+inherit
+	WSF_FILE_SYSTEM_HANDLER
+		redefine
+			initialize,
+			process_transfert
+		end
+
+create
+	make_with_path,
+	make_hidden_with_path,
+	make,
+	make_hidden
+
+feature {NONE} -- Initialization
+
+	initialize
+		do
+			Precursor
+			create compression.make
+		end
+
+feature -- Access: compression
+
+	compression: WSF_COMPRESSION
+
+feature -- Execution
+
+	process_transfert (f: FILE; req: WSF_REQUEST; res: WSF_RESPONSE)
+		local
+			ext: READABLE_STRING_32
+			ct: detachable READABLE_STRING_8
+			fres: WSF_FILE_RESPONSE_WITH_COMPRESSION
+			dt: DATE_TIME
+		do
+			ext := extension (f.path.name)
+			ct := extension_mime_mapping.mime_type (ext)
+			if ct = Void then
+				ct := {HTTP_MIME_TYPES}.application_force_download
+			end
+
+			create fres.make_with_content_type_and_path (ct, f.path)
+				-- Apply compression based on request `req` header.
+			fres.apply_compression (compression, req)
+
+				-- Prepare response
+			fres.set_status_code ({HTTP_STATUS_CODE}.ok)
+
+				-- cache control
+			create dt.make_now_utc
+			fres.header.put_utc_date (dt)
+			if max_age >= 0 then
+				fres.set_max_age (max_age)
+				if max_age > 0 then
+					dt := dt.twin
+					dt.second_add (max_age)
+				end
+				fres.set_expires_date (dt)
+			end
+
+				-- send
+			fres.set_answer_head_request_method (req.request_method.same_string ({HTTP_REQUEST_METHODS}.method_head))
+			res.send (fres)
+		end
+
+note
+	copyright: "2011-2017, Jocelyn Fiat, Javier Velilla, Olivier Ligot, Colin Adams, Eiffel Software and others"
+	license: "Eiffel Forum License v2 (see http://www.eiffel.com/licensing/forum.txt)"
+	source: "[
+			Eiffel Software
+			5949 Hollister Ave., Goleta, CA 93117 USA
+			Telephone 805-685-1006, Fax 805-685-6869
+			Website http://www.eiffel.com
+			Customer support http://support.eiffel.com
+		]"
+end

library/server/wsf/router/wsf_file_system_handler.e

@@ -39,6 +39,7 @@ feature {NONE} -- Initialization
 
 	make_with_path (d: like document_root)
 		do
+			initialize
 			max_age := -1
 			if d.is_empty then
 				document_root := execution_environment.current_working_path
@@ -73,6 +74,11 @@ feature {NONE} -- Initialization
 	is_hidden: BOOLEAN
 			-- Current mapped handler should be hidden from self documentation		
 
+	initialize
+			-- Initialize Current handler.
+		do
+		end
+
 feature -- Documentation
 
 	mapping_documentation (m: WSF_ROUTER_MAPPING; a_request_methods: detachable WSF_REQUEST_METHODS): WSF_ROUTER_MAPPING_DOCUMENTATION
@@ -211,7 +217,7 @@ feature -- Execution
 			fn := resource_filename (uri)
 			create f.make_with_path (fn)
 			if f.exists then
-				if f.is_readable then
+				if f.is_access_readable then
 					if f.is_directory then
 						if index_disabled then
 							process_directory_index_disabled (uri, req, res)
@@ -341,6 +347,8 @@ feature -- Execution
 		end
 
 	process_file (f: FILE; req: WSF_REQUEST; res: WSF_RESPONSE)
+		require
+			f_valid: f.exists and then f.is_access_readable
 		do
 			if
 				attached req.meta_string_variable ("HTTP_IF_MODIFIED_SINCE") as s_if_modified_since and then
@@ -355,6 +363,8 @@ feature -- Execution
 		end
 
 	process_transfert (f: FILE; req: WSF_REQUEST; res: WSF_RESPONSE)
+		require
+			f_valid: f.exists and then f.is_access_readable
 		local
 			ext: READABLE_STRING_32
 			ct: detachable READABLE_STRING_8

library/server/wsf/src/response/wsf_file_response.e

@@ -104,6 +104,15 @@ feature {NONE} -- Initialization
 
 feature -- Element change
 
+	set_content_type (a_content_type: detachable like content_type)
+		do
+			if a_content_type = Void then
+				get_content_type
+			else
+				content_type := a_content_type
+			end
+		end
+
 	set_max_age (sec: INTEGER)
 		do
 			header.put_cache_control ("max-age=" + sec.out)
@@ -227,6 +236,7 @@ feature {WSF_RESPONSE} -- Output
 		do
 			res.set_status_code (status_code)
 			if status_code = {HTTP_STATUS_CODE}.not_found then
+					-- File not found, then no more data.
 			else
 				res.put_header_text (header.string)
 				s := head

library/server/wsf/wsf_compression-safe.ecf

@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="ISO-8859-1"?>
+<system xmlns="http://www.eiffel.com/developers/xml/configuration-1-15-0" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.eiffel.com/developers/xml/configuration-1-15-0 http://www.eiffel.com/developers/xml/configuration-1-15-0.xsd" name="wsf_compression" uuid="C558E537-1259-4C94-8C49-117D7E821820" library_target="wsf_compression">
+	<target name="wsf_compression">
+		<root all_classes="true"/>
+		<file_rule>
+			<exclude>/.git$</exclude>
+			<exclude>/.svn$</exclude>
+			<exclude>/EIFGENs$</exclude>
+		</file_rule>
+		<option warning="true" void_safety="all">
+		</option>
+		<setting name="concurrency" value="scoop"/>
+		<library name="base" location="$ISE_LIBRARY\library\base\base-safe.ecf"/>
+		<library name="conneg" location="..\..\network\protocol\content_negotiation\conneg-safe.ecf"/>
+		<library name="http" location="..\..\network\protocol\http\http-safe.ecf"/>
+		<library name="wsf" location="wsf-safe.ecf" readonly="false"/>
+		<library name="time" location="$ISE_LIBRARY\library\time\time-safe.ecf"/>
+		<library name="zlib" location="$ISE_LIBRARY\unstable\library\compression\zlib\zlib-safe.ecf" readonly="false"/>
+		<cluster name="compression" location=".\compression\" recursive="true"/>
+	</target>
+</system>

library/server/wsf/wsf_compression.ecf

@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="ISO-8859-1"?>
+<system xmlns="http://www.eiffel.com/developers/xml/configuration-1-15-0" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.eiffel.com/developers/xml/configuration-1-15-0 http://www.eiffel.com/developers/xml/configuration-1-15-0.xsd" name="wsf_compression" uuid="C558E537-1259-4C94-8C49-117D7E821820" library_target="wsf_compression">
+	<target name="wsf_compression">
+		<root all_classes="true"/>
+		<file_rule>
+			<exclude>/.git$</exclude>
+			<exclude>/.svn$</exclude>
+			<exclude>/EIFGENs$</exclude>
+		</file_rule>
+		<option warning="true" void_safety="none">
+		</option>
+		<setting name="concurrency" value="scoop"/>
+		<library name="base" location="$ISE_LIBRARY\library\base\base.ecf"/>
+		<library name="conneg" location="..\..\network\protocol\content_negotiation\conneg.ecf"/>
+		<library name="wsf" location="wsf.ecf"/>
+		<cluster name="compression" location=".\compression\" recursive="true"/>
+	</target>
+</system>

tests/dev/hello-safe.ecf

@@ -24,7 +24,6 @@
 		</option>
 		<library name="default_standalone" location="..\..\library\server\wsf\default\standalone-safe.ecf" readonly="false" use_application_options="true"/>
 		<cluster name="src" location="src\" recursive="true"/>
-		<override name="override" location="override\" recursive="true"/>
 	</target>
 	<target name="hello_cgi" extends="hello_dev">
 		<library name="default_cgi" location="..\..\library\server\wsf\default\cgi-safe.ecf"/>

tools/requestbin/README.md

@@ -1 +0,0 @@
-This example is a simple service that analyze the request and return a formatted output of the request data (query parameters, form parameters, environment variables, and so on). It could be used to debug client, or to experiment the EiffelWeb behavior on various connectors (standalone, apache, iis, ...).

tools/requestbin/launcher/any/application_launcher.e

@@ -1,19 +0,0 @@
-note
-	description: "[
-				Effective class for APPLICATION_LAUNCHER_I
-
-				You can put modification in this class
-			]"
-	date: "$Date: 2013-06-12 13:55:42 +0200 (mer., 12 juin 2013) $"
-	revision: "$Revision: 36 $"
-
-class
-	APPLICATION_LAUNCHER [G -> WSF_EXECUTION create make end]
-
-inherit
-	APPLICATION_LAUNCHER_I [G]
-
-feature -- Custom
-
-end
-

tools/requestbin/launcher/any/application_launcher_i.e

@@ -1,102 +0,0 @@
-note
-	description: "[
-			Specific application launcher
-
-			DO NOT EDIT THIS CLASS
-
-			you can customize APPLICATION_LAUNCHER
-		]"
-	date: "$Date: 2013-06-12 13:55:42 +0200 (mer., 12 juin 2013) $"
-	revision: "$Revision: 36 $"
-
-deferred class
-	APPLICATION_LAUNCHER_I [G -> WSF_EXECUTION create make end]
-
-inherit
-	SHARED_EXECUTION_ENVIRONMENT
-
-feature -- Execution
-
-	launch (opts: detachable WSF_SERVICE_LAUNCHER_OPTIONS)
-		local
-			nature: like launcher_nature
-		do
-			nature := launcher_nature
-			if nature = Void or else nature = nature_standalone then
-				launch_standalone (opts)
-			elseif nature = nature_cgi then
-				launch_cgi (opts)
-			elseif nature = nature_libfcgi then
-				launch_libfcgi (opts)
-			else
-				-- bye bye
-				(create {EXCEPTIONS}).die (-1)
-			end
-		end
-
-feature {NONE} -- Access
-
-	launcher_nature: detachable READABLE_STRING_8
-			-- Initialize the launcher nature
-			-- either cgi, libfcgi, or standalone.
-			--| We could extend with more connector if needed.
-			--| and we could use WSF_DEFAULT_SERVICE_LAUNCHER to configure this at compilation time.
-		local
-			p: PATH
-			ext: detachable READABLE_STRING_32
-		do
-			create p.make_from_string (execution_environment.arguments.command_name)
-			if attached p.entry as l_entry then
-				ext := l_entry.extension
-			end
-			if ext /= Void then
-				if ext.same_string (nature_standalone) then
-					Result := nature_standalone
-				end
-				if ext.same_string (nature_cgi) then
-					Result := nature_cgi
-				end
-				if ext.same_string (nature_libfcgi) or else ext.same_string ("fcgi") then
-					Result := nature_libfcgi
-				end
-			end
-			Result := nature_standalone
-		end
-
-feature {NONE} -- Standalone
-
-	nature_standalone: STRING = "standalone"
-
-	launch_standalone (opts: detachable WSF_SERVICE_LAUNCHER_OPTIONS)
-		local
-			launcher: WSF_STANDALONE_SERVICE_LAUNCHER [G]
-		do
-			create launcher.make_and_launch (opts)
-		end
-
-feature {NONE} -- cgi
-
-	nature_cgi: STRING = "cgi"
-
-	launch_cgi (opts: detachable WSF_SERVICE_LAUNCHER_OPTIONS)
-		local
-			launcher: WSF_CGI_SERVICE_LAUNCHER [G]
-		do
-			create launcher.make_and_launch (opts)
-		end
-
-feature {NONE} -- libfcgi
-
-	nature_libfcgi: STRING = "libfcgi"
-
-	launch_libfcgi (opts: detachable WSF_SERVICE_LAUNCHER_OPTIONS)
-		local
-			launcher: WSF_LIBFCGI_SERVICE_LAUNCHER [G]
-		do
-			create launcher.make_and_launch (opts)
-		end
-
-
-end
-
-

tools/requestbin/launcher/default/application_launcher.e

@@ -1,19 +0,0 @@
-note
-	description: "[
-				Effective class for APPLICATION_LAUNCHER_I
-
-				You can put modification in this class
-			]"
-	date: "$Date: 2013-06-12 13:55:42 +0200 (mer., 12 juin 2013) $"
-	revision: "$Revision: 36 $"
-
-class
-	APPLICATION_LAUNCHER [G -> WSF_EXECUTION create make end]
-
-inherit
-	APPLICATION_LAUNCHER_I [G]
-
-feature -- Custom
-
-end
-

tools/requestbin/launcher/default/application_launcher_i.e

@@ -1,26 +0,0 @@
-note
-	description: "[
-			Specific application launcher
-
-			DO NOT EDIT THIS CLASS
-
-			you can customize APPLICATION_LAUNCHER
-		]"
-	date: "$Date: 2013-06-12 13:55:42 +0200 (mer., 12 juin 2013) $"
-	revision: "$Revision: 36 $"
-
-deferred class
-	APPLICATION_LAUNCHER_I [G -> WSF_EXECUTION create make end]
-
-feature -- Execution
-
-	launch (opts: detachable WSF_SERVICE_LAUNCHER_OPTIONS)
-		local
-			launcher: WSF_SERVICE_LAUNCHER [G]
-		do
-			create {WSF_DEFAULT_SERVICE_LAUNCHER [G]} launcher.make_and_launch (opts)
-		end
-
-end
-
-

tools/requestbin/requestbin.ecf

@@ -1,48 +0,0 @@
-<?xml version="1.0" encoding="ISO-8859-1"?>
-<system xmlns="http://www.eiffel.com/developers/xml/configuration-1-15-0" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.eiffel.com/developers/xml/configuration-1-15-0 http://www.eiffel.com/developers/xml/configuration-1-15-0.xsd" name="requestbin" uuid="FF1E47E3-7677-4E1C-9459-2E2C2341325A">
-	<target name="common" abstract="true">
-		<file_rule>
-			<exclude>/.svn$</exclude>
-			<exclude>/CVS$</exclude>
-			<exclude>/EIFGENs$</exclude>
-		</file_rule>
-		<option warning="true" void_safety="all">
-			<assertions precondition="true" postcondition="true" check="true" invariant="true" loop="true" supplier_precondition="true"/>
-		</option>
-		<setting name="console_application" value="true"/>
-		<setting name="concurrency" value="scoop"/>
-		<library name="base" location="$ISE_LIBRARY\library\base\base-safe.ecf"/>
-		<library name="encoder" location="..\..\library\text\encoder\encoder-safe.ecf" readonly="false"/>
-		<library name="http" location="..\..\library\network\protocol\http\http-safe.ecf"/>
-		<library name="wsf" location="..\..\library\server\wsf\wsf-safe.ecf" readonly="false"/>
-		<library name="wsf_extension" location="..\..\library\server\wsf\wsf_extension-safe.ecf" readonly="false"/>
-	</target>
-	<target name="requestbin_any" extends="common">
-		<root class="EWF_REQUESTBIN_SERVER" feature="make_and_launch"/>
-		<setting name="concurrency" value="scoop"/>
-		<library name="cgi" location="..\..\library\server\wsf\connector\cgi-safe.ecf" readonly="false"/>
-		<library name="libfcgi" location="..\..\library\server\wsf\connector\libfcgi-safe.ecf" readonly="false"/>
-		<library name="standalone" location="..\..\library\server\wsf\connector\standalone-safe.ecf" readonly="false"/>
-		<cluster name="launcher" location=".\launcher\any\" recursive="true"/>
-		<cluster name="src" location=".\src\" recursive="true"/>
-	</target>
-	<target name="requestbin" extends="common">
-		<root class="EWF_REQUESTBIN_SERVER" feature="make_and_launch"/>
-		<setting name="concurrency" value="scoop"/>
-		<library name="default_standalone" location="..\..\library\server\wsf\default\standalone-safe.ecf" readonly="false"/>
-		<cluster name="launcher" location=".\launcher\default\" recursive="true"/>
-		<cluster name="src" location=".\src\" recursive="true"/>
-	</target>
-	<target name="requestbin_cgi" extends="common">
-		<root class="EWF_REQUESTBIN_SERVER" feature="make_and_launch"/>
-		<library name="default_cgi" location="..\..\library\server\wsf\default\cgi-safe.ecf" readonly="false"/>
-		<cluster name="launcher" location=".\launcher\default\" recursive="true"/>
-		<cluster name="src" location=".\src\" recursive="true"/>
-	</target>
-	<target name="requestbin_libfcgi" extends="common">
-		<root class="EWF_REQUESTBIN_SERVER" feature="make_and_launch"/>
-		<library name="default_libfcgi" location="..\..\library\server\wsf\default\libfcgi-safe.ecf"/>
-		<cluster name="launcher" location=".\launcher\default\" recursive="true"/>
-		<cluster name="src" location=".\src\" recursive="true"/>
-	</target>
-</system>

tools/requestbin/server.ini

@@ -1,2 +0,0 @@
-port=9090
-verbose=true

tools/requestbin/src/ewf_debug_execution.e

@@ -1,27 +0,0 @@
-note
-	description: "Summary description for {EWF_DEBUG_EXECUTION}."
-	author: ""
-	date: "$Date$"
-	revision: "$Revision$"
-
-class
-	EWF_DEBUG_EXECUTION
-
-inherit
-	WSF_EXECUTION
-
-create
-	make
-
-feature -- Execution
-
-	execute
-		local
-			dbg: WSF_DEBUG_HANDLER
-		do
-			response.put_error ("DEBUG uri=" + request.request_uri + "%N")
-			create dbg.make
-			dbg.execute_starts_with ("", request, response)
-		end
-
-end

tools/requestbin/src/ewf_requestbin_server.e

@@ -1,35 +0,0 @@
-note
-	description: "[
-				application service
-			]"
-	date: "$Date$"
-	revision: "$Revision$"
-
-class
-	EWF_REQUESTBIN_SERVER
-
-inherit
-	WSF_LAUNCHABLE_SERVICE
-		redefine
-			initialize
-		end
-
-	APPLICATION_LAUNCHER [EWF_DEBUG_EXECUTION]
-
-create
-	make_and_launch
-
-feature {NONE} -- Initialization
-
-	initialize
-			-- Initialize current service.
-		do
-			Precursor
---			set_service_option ("verbose", True)
-			set_service_option ("port", 9090)
---			set_service_option ("base", "/www-debug/debug_service.fcgi/")
-			import_service_options (create {WSF_SERVICE_LAUNCHER_OPTIONS_FROM_INI}.make_from_file ("server.ini"))
-		end
-
-end
-